From 2725312e0301b6b999eac517fb023b13238eb155 Mon Sep 17 00:00:00 2001
From: Marc Jakobi <marc.jakobi@tiko.energy>
Date: Sat, 22 Jun 2024 22:43:13 +0200
Subject: panvimdoc: init at 4.0.1

---
 pkgs/by-name/pa/panvimdoc/package.nix | 50 +++++++++++++++++++++++++++++++++++
 1 file changed, 50 insertions(+)
 create mode 100644 pkgs/by-name/pa/panvimdoc/package.nix

diff --git a/pkgs/by-name/pa/panvimdoc/package.nix b/pkgs/by-name/pa/panvimdoc/package.nix
new file mode 100644
index 0000000000000..d31260975a94a
--- /dev/null
+++ b/pkgs/by-name/pa/panvimdoc/package.nix
@@ -0,0 +1,50 @@
+{
+  lib,
+  fetchFromGitHub,
+  stdenvNoCC,
+  pandoc,
+  vim,
+  neovim-unwrapped,
+  makeWrapper,
+}:
+
+stdenvNoCC.mkDerivation (finalAttrs: {
+  pname = "panvimdoc";
+  version = "4.0.1";
+
+  src = fetchFromGitHub {
+    owner = "kdheepak";
+    repo = "panvimdoc";
+    rev = "refs/tags/v${finalAttrs.version}";
+    hash = "sha256-HmEBPkNELHC7Xy0v730sQWZyPPwFdIBUcELzNtrWwzQ=";
+  };
+
+  nativeBuildInputs = [ makeWrapper ];
+
+  buildPhase = ''
+    runHook preBuild
+    install -Dm444 scripts/* -t $out/share/scripts
+    install -Dm444 lib/* -t $out/share/lib
+    install -Dm755 panvimdoc.sh -t $out/share
+    runHook postBuild
+  '';
+
+  postFixup = ''
+    makeWrapper $out/share/panvimdoc.sh $out/bin/panvimdoc --prefix PATH : ${
+      lib.makeBinPath [
+        pandoc
+        vim
+        neovim-unwrapped
+      ]
+    }
+  '';
+
+  meta = {
+    description = "Write documentation in pandoc markdown. Generate documentation in vimdoc";
+    homepage = "https://github.com/kdheepak/panvimdoc";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.unix;
+    maintainers = with lib.maintainers; [ mrcjkb ];
+    mainProgram = "panvimdoc";
+  };
+})
-- 
cgit 1.4.1