From 6035e80137e04d56a8766fbac964009ef919cda9 Mon Sep 17 00:00:00 2001
From: Guillaume Maudoux <layus.on@gmail.com>
Date: Sun, 31 May 2015 11:38:18 +0200
Subject: ktikz: init at 0.10

---
 pkgs/applications/graphics/ktikz/default.nix | 78 ++++++++++++++++++++++++++++
 1 file changed, 78 insertions(+)
 create mode 100644 pkgs/applications/graphics/ktikz/default.nix

(limited to 'pkgs/applications/graphics/ktikz')

diff --git a/pkgs/applications/graphics/ktikz/default.nix b/pkgs/applications/graphics/ktikz/default.nix
new file mode 100644
index 0000000000000..ea4826ffaf8e8
--- /dev/null
+++ b/pkgs/applications/graphics/ktikz/default.nix
@@ -0,0 +1,78 @@
+{ withKDE ? true
+, stdenv, fetchurl, gettext, poppler_qt4, qt4
+# Qt only (no KDE):
+, pkgconfig
+# With KDE
+, cmake, automoc4, kdelibs
+}:
+
+# Warning: You will also need a working pdflatex installation containing (at
+# least) auctex and pgf.
+
+assert withKDE -> kdelibs != null;
+
+let
+  version = "0.10";
+
+  qtikz = {
+    name = "qtikz-${version}";
+
+    conf = ''
+      # installation prefix:
+      #PREFIX = ""
+
+      # install desktop file here (*nix only):
+      DESKTOPDIR = ''$''${PREFIX}/share/applications
+
+      # install mimetype here:
+      MIMEDIR = ''$''${PREFIX}/share/mime/packages
+
+      CONFIG -= debug
+      CONFIG += release
+
+      # qmake command:
+      QMAKECOMMAND = qmake
+      # lrelease command:
+      LRELEASECOMMAND = lrelease
+      # qcollectiongenerator command:
+      #QCOLLECTIONGENERATORCOMMAND = qcollectiongenerator
+
+      # TikZ documentation default file path:
+      TIKZ_DOCUMENTATION_DEFAULT = ''$''${PREFIX}/share/doc/texmf/pgf/pgfmanual.pdf.gz
+    '';
+
+    patchPhase = ''
+      echo "$conf" > conf.pri
+    '';
+
+    configurePhase = ''
+      qmake PREFIX="$out" ./qtikz.pro
+    '';
+
+    buildInputs = [ gettext qt4 poppler_qt4 pkgconfig ];
+  };
+
+  ktikz = {
+    name = "ktikz-${version}";
+    buildInputs = [ kdelibs cmake qt4 automoc4 gettext poppler_qt4 ];
+  };
+
+  common = {
+    inherit version;
+    src = fetchurl {
+      url = "http://www.hackenberger.at/ktikz/ktikz_${version}.tar.gz";
+      md5 = "e8f0826cba2447250bcdcd389a71a2ac";
+    };
+
+    enableParallelBuilding = true;
+
+    meta = with stdenv.lib; {
+      description = "Editor for the TikZ language";
+      license = licenses.gpl2;
+      platforms = platforms.linux;
+      maintainers = [ maintainers.layus ];
+    };
+  };
+
+in stdenv.mkDerivation (common // (if withKDE then ktikz else qtikz))
+
-- 
cgit 1.4.1