From 2e59fd5ffc1a15f5a71d1593a8969f9608edca0b Mon Sep 17 00:00:00 2001
From: Mostly Void <7rat13@gmail.com>
Date: Sat, 31 Dec 2022 00:03:39 +0530
Subject: oculante: init at 0.6.38

---
 pkgs/applications/graphics/oculante/default.nix | 66 +++++++++++++++++++++++++
 1 file changed, 66 insertions(+)
 create mode 100644 pkgs/applications/graphics/oculante/default.nix

(limited to 'pkgs/applications/graphics')

diff --git a/pkgs/applications/graphics/oculante/default.nix b/pkgs/applications/graphics/oculante/default.nix
new file mode 100644
index 0000000000000..65300df69048c
--- /dev/null
+++ b/pkgs/applications/graphics/oculante/default.nix
@@ -0,0 +1,66 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, cmake
+, pkg-config
+, openssl
+, fontconfig
+, nasm
+, libX11
+, libXcursor
+, libXrandr
+, libXi
+, libGL
+, stdenv
+, gtk3
+, darwin
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "oculante";
+  version = "0.6.38";
+
+  src = fetchFromGitHub {
+    owner = "woelper";
+    repo = pname;
+    rev = version;
+    sha256 = "sha256-0msPeW0FoBzHBDfX2iFH4HzAknaGPNThuCLi2vhdK08=";
+  };
+
+  cargoSha256 = "sha256-eKRn8MC4/jjPRoajhwrtXsa8n9bGO5MAKjDuwHWs7Oc=";
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    nasm
+  ];
+
+  checkFlagsArray = [ "--skip=tests::net" ]; # requires network access
+
+  buildInputs = [
+    openssl
+    fontconfig
+  ] ++ lib.optionals stdenv.isLinux [
+    libX11
+    libXcursor
+    libXi
+    libXrandr
+    libGL
+    gtk3
+  ] ++ lib.optionals stdenv.isDarwin [
+    darwin.libobjc
+  ];
+
+  postFixup = lib.optionalString stdenv.isLinux ''
+    patchelf $out/bin/oculante --add-rpath ${lib.makeLibraryPath [ libGL ]}
+  '';
+
+  meta = with lib; {
+    broken = stdenv.isDarwin;
+    description = "A minimalistic crossplatform image viewer written in Rust";
+    homepage = "https://github.com/woelper/oculante";
+    changelog = "https://github.com/woelper/oculante/blob/${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ dit7ya ];
+  };
+}
-- 
cgit 1.4.1