From bc3d4bb2956eadef8452b06542b2d3b9ecdf5a40 Mon Sep 17 00:00:00 2001
From: Alexander Nortung <alex_nortung@live.dk>
Date: Sun, 21 Aug 2022 19:45:25 +0200
Subject: session-desktop: refactor

Renamed session-desktop-appimage to session-desktop
---
 .../instant-messengers/session-desktop/default.nix | 65 ++++++++++++++++++++++
 1 file changed, 65 insertions(+)
 create mode 100644 pkgs/applications/networking/instant-messengers/session-desktop/default.nix

(limited to 'pkgs/applications/networking/instant-messengers/session-desktop')

diff --git a/pkgs/applications/networking/instant-messengers/session-desktop/default.nix b/pkgs/applications/networking/instant-messengers/session-desktop/default.nix
new file mode 100644
index 0000000000000..0f1e9f9e8ad9f
--- /dev/null
+++ b/pkgs/applications/networking/instant-messengers/session-desktop/default.nix
@@ -0,0 +1,65 @@
+{ lib
+, makeDesktopItem
+, copyDesktopItems
+, stdenvNoCC
+, fetchurl
+, appimageTools
+, makeWrapper
+}:
+
+let
+  version = "1.9.1";
+  pname = "session-desktop";
+
+  src = fetchurl {
+    url = "https://github.com/oxen-io/session-desktop/releases/download/v${version}/session-desktop-linux-x86_64-${version}.AppImage";
+    sha256 = "sha256-Zc3btkvN4ic47IGigeFJGx4dwbM+b7iuIOxpmcWmrRQ=";
+  };
+  appimage = appimageTools.wrapType2 {
+    inherit version pname src;
+  };
+  appimage-contents = appimageTools.extractType2 {
+    inherit version pname src;
+  };
+in
+stdenvNoCC.mkDerivation {
+  inherit version pname;
+  src = appimage;
+
+  nativeBuildInputs = [ copyDesktopItems makeWrapper ];
+
+  desktopItems = [
+    (makeDesktopItem {
+      name = "Session";
+      desktopName = "Session";
+      comment = "Onion routing based messenger";
+      exec = "${appimage}/bin/session-desktop-${version}";
+      icon = "${appimage-contents}/session-desktop.png";
+      terminal = false;
+      type = "Application";
+      categories = [ "Network" ];
+    })
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    mv bin/session-desktop-${version} bin/session-desktop
+
+    mkdir -p $out/
+    cp -r bin $out/bin
+
+    wrapProgram $out/bin/session-desktop \
+      --add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--enable-features=UseOzonePlatform --ozone-platform=wayland}}"
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    description = "Onion routing based messenger";
+    homepage = "https://getsession.org/";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ alexnortung ];
+    platforms = [ "x86_64-linux" ];
+  };
+}
-- 
cgit 1.4.1