From ef0d15f8d3f5f8c11ba4af0faddbf78d43383a41 Mon Sep 17 00:00:00 2001
From: Jonas Heinrich
Date: Thu, 5 Sep 2024 08:32:42 +0200
Subject: wasm-bingen-cli: 0.2.92 -> 0.2.93

---
 pkgs/by-name/wa/wasm-bindgen-cli/package.nix | 49 ++++++++++++++++++++++++++++
 1 file changed, 49 insertions(+)
 create mode 100644 pkgs/by-name/wa/wasm-bindgen-cli/package.nix

(limited to 'pkgs/by-name/wa')

diff --git a/pkgs/by-name/wa/wasm-bindgen-cli/package.nix b/pkgs/by-name/wa/wasm-bindgen-cli/package.nix
new file mode 100644
index 000000000000..517b2813478f
--- /dev/null
+++ b/pkgs/by-name/wa/wasm-bindgen-cli/package.nix
@@ -0,0 +1,49 @@
+{
+  lib,
+  rustPlatform,
+  fetchCrate,
+  nix-update-script,
+  nodejs_latest,
+  pkg-config,
+  openssl,
+  stdenv,
+  curl,
+  darwin,
+  version ? "0.2.93",
+  hash ? "sha256-DDdu5mM3gneraM85pAepBXWn3TMofarVR4NbjMdz3r0=",
+  cargoHash ? "sha256-birrg+XABBHHKJxfTKAMSlmTVYLmnmqMDfRnmG6g/YQ=",
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "wasm-bindgen-cli";
+  inherit version hash cargoHash;
+
+  src = fetchCrate { inherit pname version hash; };
+
+  nativeBuildInputs = [ pkg-config ];
+
+  buildInputs =
+    [ openssl ]
+    ++ lib.optionals stdenv.isDarwin [
+      curl
+      darwin.apple_sdk.frameworks.Security
+    ];
+
+  nativeCheckInputs = [ nodejs_latest ];
+
+  # tests require it to be ran in the wasm-bindgen monorepo
+  doCheck = false;
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    homepage = "https://rustwasm.github.io/docs/wasm-bindgen/";
+    license = with lib.licenses; [
+      asl20 # or
+      mit
+    ];
+    description = "Facilitating high-level interactions between wasm modules and JavaScript";
+    maintainers = with lib.maintainers; [ rizary ];
+    mainProgram = "wasm-bindgen";
+  };
+}
-- 
cgit 1.4.1