From 7321c7cb6f8631dc2ab7e17cf94e028f347b064a Mon Sep 17 00:00:00 2001
From: Ilya Epifanov <mail@ilya.network>
Date: Mon, 13 May 2024 10:35:12 +0200
Subject: onagre: moved to pkgs/by-name

---
 pkgs/by-name/on/onagre/package.nix | 58 ++++++++++++++++++++++++++++++++++++++
 1 file changed, 58 insertions(+)
 create mode 100644 pkgs/by-name/on/onagre/package.nix

(limited to 'pkgs/by-name')

diff --git a/pkgs/by-name/on/onagre/package.nix b/pkgs/by-name/on/onagre/package.nix
new file mode 100644
index 0000000000000..2943e8f032941
--- /dev/null
+++ b/pkgs/by-name/on/onagre/package.nix
@@ -0,0 +1,58 @@
+{ lib
+, fetchFromGitHub
+, makeWrapper
+, rustPlatform
+, cmake
+, pkgconf
+, freetype
+, expat
+, wayland
+, xorg
+, libxkbcommon
+, pop-launcher
+, vulkan-loader
+, libGL
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "onagre";
+  version = "1.1.0";
+
+  src = fetchFromGitHub {
+    owner = "onagre-launcher";
+    repo = "onagre";
+    rev = "1.1.0";
+    hash = "sha256-ASeLvgj2RyhsZQtkUTYeA7jWyhbLg8yl6HbN2A/Sl2M=";
+  };
+
+  cargoHash = "sha256-17Hw3jtisOXwARpp0jB0hrNax7nzMWS0kCE3ZAruBj8=";
+
+  nativeBuildInputs = [ makeWrapper cmake pkgconf ];
+  buildInputs = [
+    expat
+    freetype
+    xorg.libX11
+    xorg.libXcursor
+    xorg.libXi
+    xorg.libXrandr
+  ];
+
+  postFixup = let
+    rpath = lib.makeLibraryPath [ libGL vulkan-loader wayland libxkbcommon ];
+  in ''
+    patchelf --set-rpath ${rpath} $out/bin/onagre
+    wrapProgram $out/bin/onagre \
+      --prefix PATH ':' ${lib.makeBinPath [
+        pop-launcher
+      ]}
+  '';
+
+  meta = with lib; {
+    description = "A general purpose application launcher for X and wayland inspired by rofi/wofi and alfred";
+    homepage = "https://github.com/onagre-launcher/onagre";
+    license = licenses.mit;
+    maintainers = [ maintainers.jfvillablanca maintainers.ilya-epifanov ];
+    platforms = platforms.linux;
+    mainProgram = "onagre";
+  };
+}
-- 
cgit 1.4.1