From 8129b1d754961a1cfa8dfd6c6d81e040a3ae973e Mon Sep 17 00:00:00 2001
From: midchildan <git@midchildan.org>
Date: Sun, 4 Oct 2020 17:12:40 +0900
Subject: aribb25: init at 0.2.7 (#96553)

* aribb25: init at 0.2.7

* fixup! aribb25: init at 0.2.7
---
 pkgs/development/libraries/aribb25/default.nix | 57 ++++++++++++++++++++++++++
 1 file changed, 57 insertions(+)
 create mode 100644 pkgs/development/libraries/aribb25/default.nix

(limited to 'pkgs/development/libraries/aribb25')

diff --git a/pkgs/development/libraries/aribb25/default.nix b/pkgs/development/libraries/aribb25/default.nix
new file mode 100644
index 0000000000000..ceae869854563
--- /dev/null
+++ b/pkgs/development/libraries/aribb25/default.nix
@@ -0,0 +1,57 @@
+{ stdenv
+, lib
+, fetchFromGitLab
+, fetchpatch
+, autoreconfHook
+, pkgconfig
+, pcsclite
+, PCSC
+, xcbuild
+}:
+
+stdenv.mkDerivation rec {
+  pname = "aribb25";
+  # FIXME: change the rev for fetchFromGitLab in next release
+  version = "0.2.7";
+
+  src = fetchFromGitLab {
+    domain = "code.videolan.org";
+    owner = "videolan";
+    repo = pname;
+    # rev = version; FIXME: uncomment in next release
+    rev = "c14938692b313b5ba953543fd94fd1cad0eeef18"; # 0.2.7 with build fixes
+    sha256 = "1kb9crfqib0npiyjk4zb63zqlzbhqm35nz8nafsvdjd71qbd2amp";
+  };
+
+  nativeBuildInputs = [
+    autoreconfHook
+    pkgconfig
+  ] ++ lib.optional stdenv.isDarwin xcbuild;
+  buildInputs = if stdenv.isDarwin then [ PCSC ] else [ pcsclite ];
+
+  patches = let
+    url = commit: "https://code.videolan.org/videolan/${pname}/-/commit/${commit}.diff";
+  in [
+    (fetchpatch {
+      name = "make-cli-pipes-work-1.patch";
+      url = url "0425184dbf3fdaf59854af5f530da88b2196a57b";
+      sha256 = "0ysm2jivpnqxz71vw1102616qxww2gx005i0c5lhi6jbajqsa1cd";
+    })
+    (fetchpatch {
+      name = "make-cli-pipes-work-2.patch";
+      url = url "cebabeab2bda065dca1c9f033b42d391be866d86";
+      sha256 = "1283kqv1r4rbaba0sv2hphkhcxgjkmh8ndlcd24fhx43nn63hd28";
+    })
+  ];
+
+  buildFlags =
+    lib.optional stdenv.isDarwin "pcsclite_CFLAGS=-I${PCSC}/Library/Frameworks/PCSC.framework/Headers";
+
+  meta = with stdenv.lib; {
+    homepage = "https://code.videolan.org/videolan/aribb25";
+    description = "Sample implementation of the ARIB STD-B25 standard";
+    platforms = platforms.all;
+    license = licenses.isc;
+    maintainers = with maintainers; [ midchildan ];
+  };
+}
-- 
cgit 1.4.1