From f1221507f37279e8e3e70582603107e3dd6d5b70 Mon Sep 17 00:00:00 2001
From: Janne Heß <janne@hess.ooo>
Date: Sat, 1 Feb 2020 17:24:41 +0100
Subject: wimboot: Init at 2.6.0

---
 pkgs/tools/misc/wimboot/default.nix | 47 +++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 pkgs/tools/misc/wimboot/default.nix

(limited to 'pkgs/tools/misc/wimboot')

diff --git a/pkgs/tools/misc/wimboot/default.nix b/pkgs/tools/misc/wimboot/default.nix
new file mode 100644
index 0000000000000..a63fa4106345e
--- /dev/null
+++ b/pkgs/tools/misc/wimboot/default.nix
@@ -0,0 +1,47 @@
+{ stdenv, fetchFromGitHub, fetchpatch, libbfd, zlib, libiberty }:
+
+stdenv.mkDerivation rec {
+  pname = "wimboot";
+  version = "2.6.0";
+
+  src = fetchFromGitHub {
+    owner = "ipxe";
+    repo = "wimboot";
+    rev = "v${version}";
+    sha256 = "134wqqr147az5vbj4szd0xffwa99b4rar7w33zm3119zsn7sd79k";
+  };
+
+  NIX_CFLAGS_COMPILE = "-Wno-address-of-packed-member"; # Fails on gcc9
+
+  patches = [
+    # Fix for newer binutils
+    (fetchpatch {
+      url =
+        "https://github.com/ipxe/wimboot/commit/91be50c17d4d9f463109d5baafd70f9fdadd86db.patch";
+      sha256 = "113448n49hmk8nz1dxbhxiciwl281zwalvb8z5p9xfnjvibj8274";
+    })
+  ];
+
+  # We cannot use sourceRoot because the patch wouldn't apply
+  postPatch = ''
+    cd src
+  '';
+
+  hardeningDisable = [ "pic" ];
+
+  buildInputs = [ libbfd zlib libiberty ];
+  makeFlags = [ "wimboot.x86_64.efi" ];
+
+  installPhase = ''
+    mkdir -p $out/share/wimboot/
+    cp wimboot.x86_64.efi $out/share/wimboot
+  '';
+
+  meta = with stdenv.lib; {
+    homepage = "https://ipxe.org/wimboot";
+    description = "Windows Imaging Format bootloader";
+    license = licenses.gpl2;
+    maintainers = with maintainers; [ das_j ajs124 ];
+    platforms = platforms.x86; # Fails on aarch64
+  };
+}
-- 
cgit 1.4.1