From ef77b61f75c9f599c71f9bb69eef71c5326b0978 Mon Sep 17 00:00:00 2001
From: Peter Hoeg <peter@hoeg.com>
Date: Thu, 1 Jun 2017 19:11:21 +0800
Subject: kwalletcli: init at 3.00

---
 pkgs/tools/security/kwalletcli/default.nix | 55 ++++++++++++++++++++++++++++++
 1 file changed, 55 insertions(+)
 create mode 100644 pkgs/tools/security/kwalletcli/default.nix

(limited to 'pkgs/tools/security/kwalletcli')

diff --git a/pkgs/tools/security/kwalletcli/default.nix b/pkgs/tools/security/kwalletcli/default.nix
new file mode 100644
index 0000000000000..c6217024f1b71
--- /dev/null
+++ b/pkgs/tools/security/kwalletcli/default.nix
@@ -0,0 +1,55 @@
+{
+  kdeDerivation, kdeWrapper, fetchurl, lib,
+  pkgconfig,
+  kcoreaddons, ki18n, kwallet,
+  mksh
+}:
+
+let
+  pname = "kwalletcli";
+  version = "3.00";
+
+  unwrapped = kdeDerivation rec {
+    name = "${pname}-${version}";
+
+    src = fetchurl {
+      url = "https://www.mirbsd.org/MirOS/dist/hosted/kwalletcli/${name}.tar.gz";
+      sha256 = "1q87nm7pkmgvkrml6hgbmv0ddx3871w7x86gn90sjc3vw59qfh98";
+    };
+
+    postPatch = ''
+      substituteInPlace GNUmakefile \
+        --replace '-I/usr/include/KF5/KCoreAddons' '-I${kcoreaddons.dev}/include/KF5/KCoreAddons' \
+        --replace '-I/usr/include/KF5/KI18n'       '-I${ki18n.dev}/include/KF5/KI18n' \
+        --replace '-I/usr/include/KF5/KWallet'     '-I${kwallet.dev}/include/KF5/KWallet' \
+        --replace /usr/bin                         $out/bin \
+        --replace /usr/share/man                   $out/share/man
+    '';
+
+    makeFlags = [ "KDE_VER=5" ];
+
+    # we need this when building against qt 5.8+
+    NIX_CFLAGS_COMPILE = [ "-std=c++11" ];
+
+    nativeBuildInputs = [ pkgconfig ];
+    # if using just kwallet, cmake will be added as a buildInput and fail the build
+    propagatedBuildInputs = [ kcoreaddons ki18n (lib.getLib kwallet) ];
+
+    preInstall = ''
+      mkdir -p $out/bin $out/share/man/man1
+    '';
+
+    meta = with lib; {
+      description = "Command-Line Interface to the KDE Wallet";
+      homepage = http://www.mirbsd.org/kwalletcli.htm;
+      license = licenses.miros;
+      maintainers = with maintainers; [ peterhoeg ];
+    };
+  };
+
+in kdeWrapper {
+  inherit unwrapped;
+  targets = map (b: "bin/" + b)
+    [ "kwalletaskpass" "kwalletcli" "kwalletcli_getpin" "pinentry-kwallet" ];
+  paths = [ mksh ];
+}
-- 
cgit 1.4.1