From 207e7e254e2549b20f910a3b2f19800b3a4c5519 Mon Sep 17 00:00:00 2001
From: paki23 <pk93@posteo.net>
Date: Sun, 11 Sep 2022 21:36:58 +0200
Subject: ludusavi: init at 0.15.0

Co-authored-by: Azat Bahawi <azat+github@bahawi.net>
---
 pkgs/applications/backup/ludusavi/default.nix | 85 +++++++++++++++++++++++++++
 pkgs/top-level/all-packages.nix               |  2 +
 2 files changed, 87 insertions(+)
 create mode 100644 pkgs/applications/backup/ludusavi/default.nix

(limited to 'pkgs')

diff --git a/pkgs/applications/backup/ludusavi/default.nix b/pkgs/applications/backup/ludusavi/default.nix
new file mode 100644
index 0000000000000..e7826fc6e949c
--- /dev/null
+++ b/pkgs/applications/backup/ludusavi/default.nix
@@ -0,0 +1,85 @@
+{ lib
+, rustPlatform
+, fetchFromGitHub
+, cmake
+, pkg-config
+, makeWrapper
+, bzip2
+, fontconfig
+, freetype
+, libGL
+, libX11
+, libXcursor
+, libXrandr
+, libXi
+, gnome
+, kdialog
+}:
+
+rustPlatform.buildRustPackage rec {
+  pname = "ludusavi";
+  version = "0.15.0";
+
+  src = fetchFromGitHub {
+    owner = "mtkennerly";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-3nh1EhjiH+dUBw3CNeFSg/+Wkxr5AYgVdM1HzVKbqJI=";
+  };
+
+  cargoSha256 = "sha256-l9jYqmKC0GJL9MSRbrNng4rO6/dx4q8EVCxfuin4v6E=";
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    makeWrapper
+  ];
+
+  buildInputs = [
+    fontconfig
+    freetype
+    libX11
+    libXcursor
+    libXrandr
+    libXi
+  ];
+
+  postInstall = ''
+    install -Dm644 assets/com.github.mtkennerly.ludusavi.metainfo.xml -t \
+      "$out/share/metainfo/"
+    install -Dm644 assets/icon.png \
+      "$out/share/icons/hicolor/64x64/apps/${pname}.png"
+    install -Dm644 assets/icon.svg \
+      "$out/share/icons/hicolor/scalable/apps/${pname}.svg"
+    install -Dm644 "assets/${pname}.desktop" -t "$out/share/applications/"
+    install -Dm644 assets/MaterialIcons-Regular.ttf -t "$out/share/fonts/TTF/"
+    install -Dm644 LICENSE -t "$out/share/licenses/${pname}/"
+  '';
+
+  postFixup =
+    let
+      libPath = lib.makeLibraryPath [
+        libGL
+        bzip2
+        fontconfig
+        freetype
+        libX11
+        libXcursor
+        libXrandr
+        libXi
+      ];
+    in
+    ''
+      patchelf --set-rpath "${libPath}" "$out/bin/$pname"
+      wrapProgram $out/bin/$pname --prefix PATH : ${lib.makeBinPath [ gnome.zenity kdialog ]}
+    '';
+
+
+  meta = with lib; {
+    description = "Backup tool for PC game saves";
+    homepage = "https://github.com/mtkennerly/ludusavi";
+    changelog = "https://github.com/mtkennerly/ludusavi/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ pasqui23 ];
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 93ddf1774edf6..25823d77f6c2d 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -1589,6 +1589,8 @@ with pkgs;
 
   libmirage = callPackage ../applications/emulators/cdemu/libmirage.nix { };
 
+  ludusavi = callPackage ../applications/backup/ludusavi { };
+
   maiko = callPackage ../applications/emulators/maiko { };
 
   mame = libsForQt5.callPackage ../applications/emulators/mame {
-- 
cgit 1.4.1