blob: b65f41d9a96d801de8458155674c8c864ddc2f89 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
|
{ lib
, stdenv
, fetchFromGitHub
, substituteAll
, cinnamon
, gettext
, gobject-introspection
, mpv
, python3
, wrapGAppsHook
}:
stdenv.mkDerivation rec {
pname = "hypnotix";
version = "2.9";
src = fetchFromGitHub {
owner = "linuxmint";
repo = "hypnotix";
rev = version;
hash = "sha256-jjCyO6lyhqH4xeNp5uy/KqNr5Mvv+45pJGHFOXNi0rk=";
};
patches = [
(substituteAll {
src = ./libmpv-path.patch;
libmpv = "${lib.getLib mpv}/lib/libmpv${stdenv.hostPlatform.extensions.sharedLibrary}";
})
];
postPatch = ''
substituteInPlace usr/lib/hypnotix/hypnotix.py \
--replace __DEB_VERSION__ ${version} \
--replace /usr/share/hypnotix $out/share/hypnotix
'';
nativeBuildInputs = [
gettext
gobject-introspection
python3.pkgs.wrapPython
wrapGAppsHook
];
dontWrapGApps = true;
buildInputs = [
cinnamon.xapps
];
pythonPath = with python3.pkgs; [
imdbpy
pygobject3
requests
setproctitle
unidecode
xapp
];
installPhase = ''
runHook preInstall
mkdir -p $out
cp -r usr/lib $out
cp -r usr/share $out
glib-compile-schemas $out/share/glib-2.0/schemas
runHook postInstall
'';
preFixup = ''
buildPythonPath "$out $pythonPath"
makeWrapper ${python3.interpreter} $out/bin/hypnotix \
--add-flags $out/lib/hypnotix/hypnotix.py \
--prefix PYTHONPATH : "$program_PYTHONPATH" \
''${gappsWrapperArgs[@]}
'';
meta = {
description = "IPTV streaming application";
homepage = "https://github.com/linuxmint/hypnotix";
changelog = "https://github.com/linuxmint/hypnotix/blob/${src.rev}/debian/changelog";
license = lib.licenses.gpl3Plus;
maintainers = with lib.maintainers; [ dotlambda ];
platforms = lib.platforms.linux;
};
}
|