pkgs/desktops/kde-4.6/kde-package/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50

{ stdenv, fetchurl, release }:

rec {
  inherit release;

  manifest = import (./manifest + "-${release}.nix");

  defaultArgs = { module, name ? module, ... }:

    (
      {
        name = "${name}-${release}";

        src = fetchurl {
          url = "mirror://kde/" + (if manifest.stable then "" else "un")
            + "stable/${release}/src/${module}-${release}.tar.bz2";
          sha256 = builtins.getAttr module manifest.packages;
        };

        meta = {
          maintainers = with stdenv.lib.maintainers; [ sander urkud ];
          platforms = stdenv.lib.platforms.linux;
        };
      } // (if module == name then { } else {
        cmakeFlags = ''
          -DDISABLE_ALL_OPTIONAL_SUBDIRECTORIES=TRUE
          -DBUILD_doc=TRUE -DBUILD_${name}=TRUE'';
      })
    );

  package = a@{meta, ...}:
    assert a.meta ? kde;
    let
      default = defaultArgs a.meta.kde;
    in
# hand-written merge
    stdenv.mkDerivation (
      default
        // removeAttrs a [ "meta" "cmakeFlags" ]
        // {
          meta = default.meta // a.meta;
        }
        // (if default ? cmakeFlags || a ? cmakeFlags then {
          cmakeFlags =
            (if default ? cmakeFlags then "${default.cmakeFlags}" else "")
            + (if default ? cmakeFlags && a ? cmakeFlags then " " else "")
            + (if a ? cmakeFlags then a.cmakeFlags else "");
        } else { }
      ));
}