liblangtag: init at 0.6.1

2 files changed, 57 insertions, 0 deletions

diff --git a/pkgs/development/libraries/liblangtag/default.nix b/pkgs/development/libraries/liblangtag/default.nix
new file mode 100644
index 0000000000000..6d9085e1741bc
--- /dev/null
+++ b/pkgs/development/libraries/liblangtag/default.nix
@@ -0,0 +1,52 @@
+{stdenv, fetchurl, fetchFromBitbucket, autoreconfHook, gtkdoc, gettext
+, pkgconfig, glib, libxml2, gobjectIntrospection, gnome-common, unzip
+}:
+
+stdenv.mkDerivation rec {
+  name = "${pname}-${version}";
+  pname = "liblangtag";
+  version = "0.6.1";
+
+  src = fetchFromBitbucket {
+    owner = "tagoh";
+    repo = "${pname}";
+    rev = "${version}";
+    sha256 = "19dk2qsg7f3ig9xz8d73jvikmf5kvrwi008wrz2psxinbdml442g";
+  };
+
+  core_zip = fetchurl {
+    # please update if an update is available
+    url = "http://www.unicode.org/Public/cldr/33/core.zip";
+    sha256 = "1faq1p5dmxpkczz6cjfsry7piksgym19cq2kf4jj2v885h490d7s";
+  };
+
+  language_subtag_registry = fetchurl {
+    url = "http://www.iana.org/assignments/language-subtag-registry";
+    sha256 = "1qfkvllyqcy40vmnvjn5w9fxw7g6ww46cb306vkgcfghnjjfhv3b";
+  };
+
+  postPatch = ''
+    gtkdocize
+    cp "${core_zip}" data/core.zip
+    touch data/stamp-core-zip
+    cp "${language_subtag_registry}" data/language-subtag-registry
+  '';
+
+  configureFlags = [
+    ''--with-locale-alias=${stdenv.cc.libc}/share/locale/locale.alias''
+  ];
+
+  buildInputs = [ gettext glib libxml2 gobjectIntrospection gnome-common 
+    unzip ];
+  nativeBuildInputs = [ autoreconfHook gtkdoc gettext pkgconfig ];
+
+  meta = {
+    inherit version;
+    description = "An interface library to access tags for identifying languages";
+    license = stdenv.lib.licenses.mpl20;
+    maintainers = [stdenv.lib.maintainers.raskin];
+    platforms = stdenv.lib.platforms.linux;
+    # There are links to a homepage that are broken by a BitBucket change
+    homepage = "https://bitbucket.org/tagoh/liblangtag/overview";
+  };
+}
diff --git a/pkgs/top-level/all-packages.nix b/pkgs/top-level/all-packages.nix
index 11f0d4ae42391..6cf98f3f7a7c2 100644
--- a/pkgs/top-level/all-packages.nix
+++ b/pkgs/top-level/all-packages.nix
@@ -3466,6 +3466,11 @@ with pkgs;
 
   libite = callPackage ../development/libraries/libite { };
 
+  liblangtag = callPackage ../development/libraries/liblangtag {
+    inherit (gnome2) gtkdoc;
+    inherit (gnome3) gnome-common;
+  };
+
   liblouis = callPackage ../development/libraries/liblouis { };
 
   liboauth = callPackage ../development/libraries/liboauth { };