nixos/thunar: init

- Add a module for the thunar file manager, which depends on the xfconf dbus service, and also has a dbus service and a systemd unit.

- Renames the option services.xserver.desktopManager.xfce.thunarPlugins to programs.thunar.plugins.

1 files changed, 44 insertions, 0 deletions

diff --git a/nixos/modules/programs/thunar.nix b/nixos/modules/programs/thunar.nix
new file mode 100644
index 0000000000000..343f84698672a
--- /dev/null
+++ b/nixos/modules/programs/thunar.nix
@@ -0,0 +1,44 @@
+{ config, lib, pkgs, ... }:
+
+with lib;
+
+let cfg = config.programs.thunar;
+
+in {
+  meta = {
+    maintainers = teams.xfce.members;
+  };
+
+  options = {
+    programs.thunar = {
+      enable = mkEnableOption "Thunar, the Xfce file manager";
+
+      plugins = mkOption {
+        default = [];
+        type = types.listOf types.package;
+        description = "List of thunar plugins to install.";
+        example = literalExpression "with pkgs.xfce; [ thunar-archive-plugin thunar-volman ]";
+      };
+
+    };
+  };
+
+  config = mkIf cfg.enable (
+    let package = pkgs.xfce.thunar.override { thunarPlugins = cfg.plugins; };
+
+    in {
+      environment.systemPackages = [
+        package
+      ];
+
+      services.dbus.packages = [
+        package
+        pkgs.xfce.xfconf
+      ];
+
+      systemd.packages = [
+        package
+      ];
+    }
+  );
+}