atmos: init at 1.4.28

1 files changed, 40 insertions, 0 deletions

diff --git a/pkgs/applications/networking/cluster/atmos/default.nix b/pkgs/applications/networking/cluster/atmos/default.nix
new file mode 100644
index 0000000000000..1e4c86bec1e67
--- /dev/null
+++ b/pkgs/applications/networking/cluster/atmos/default.nix
@@ -0,0 +1,40 @@
+{ lib, buildGoModule, fetchFromGitHub }:
+
+buildGoModule rec {
+  pname = "atmos";
+  version = "1.4.28";
+
+  src = fetchFromGitHub {
+    owner = "cloudposse";
+    repo = pname;
+    rev = "v${version}";
+    sha256 = "sha256-AqW//+x1tKzm5dJirXCLFuDBTk3dHHw7c6vwsVsI37U";
+  };
+
+  vendorSha256 = "sha256-bepv8Ns8vcpLpmO7fsRgGijB9B6kQ5HhxUhIuEpGtOY=";
+
+  ldflags = [ "-s" "-w" "-X github.com/cloudposse/atmos/cmd.Version=v${version}" ];
+
+  preCheck = ''
+    # Remove tests that depend on a network connection.
+    rm -f pkg/vender/component_vendor_test.go
+  '';
+
+  doCheck = true;
+
+  doInstallCheck = true;
+  installCheckPhase = ''
+    runHook preInstallCheck
+    $out/bin/atmos version | grep "v${version}"
+    runHook postInstallCheck
+  '';
+
+  meta = with lib; {
+    homepage = "https://atmos.tools";
+    changelog = "https://github.com/cloudposse/atmos/releases/tag/v${version}";
+    description = "Universal Tool for DevOps and Cloud Automation (works with terraform, helm, helmfile, etc)";
+    license = licenses.asl20;
+    maintainers = with maintainers; [ rb ];
+  };
+}
+