Merge pull request #237494 from Icy-Thought/upscayl

upscayl: init at 2.5.5

1 files changed, 42 insertions, 0 deletions

diff --git a/pkgs/applications/graphics/upscayl/default.nix b/pkgs/applications/graphics/upscayl/default.nix
new file mode 100644
index 0000000000000..f4ec256aecb8a
--- /dev/null
+++ b/pkgs/applications/graphics/upscayl/default.nix
@@ -0,0 +1,42 @@
+{
+  appimageTools,
+  fetchurl,
+  lib,
+}: let
+  pname = "upscayl";
+  version = "2.5.5";
+
+  src = fetchurl {
+    url = "https://github.com/upscayl/upscayl/releases/download/v${version}/upscayl-${version}-linux.AppImage";
+    hash = "sha256-qpLxOGphR9iHvtb8AZZaMict/g8wLkL7Dhr4mt3LZdk=";
+  };
+
+  appimageContents = appimageTools.extractType2 {
+    inherit pname version src;
+  };
+in
+  appimageTools.wrapType2 {
+    inherit pname version src;
+
+    extraPkgs = pkgs: with pkgs; [vulkan-headers vulkan-loader];
+
+    extraInstallCommands = ''
+      mkdir -p $out/share/{applications,pixmaps}
+
+      cp ${appimageContents}/${pname}.desktop $out/share/applications/${pname}.desktop
+      cp ${appimageContents}/${pname}.png $out/share/pixmaps/${pname}.png
+
+      mv $out/bin/${pname}-${version} $out/bin/${pname}
+
+      substituteInPlace $out/share/applications/${pname}.desktop \
+        --replace 'Exec=AppRun --no-sandbox %U' 'Exec=${pname}'
+    '';
+
+    meta = with lib; {
+      description = "Free and Open Source AI Image Upscaler";
+      homepage = "https://upscayl.github.io/";
+      maintainers = with maintainers; [icy-thought];
+      license = licenses.agpl3Only;
+      platforms = platforms.linux;
+    };
+  }