dooit: pkgs/tools/misc -> pkgs/by-name

1 files changed, 60 insertions, 0 deletions

diff --git a/pkgs/by-name/do/dooit/package.nix b/pkgs/by-name/do/dooit/package.nix
new file mode 100644
index 0000000000000..c532b13877d30
--- /dev/null
+++ b/pkgs/by-name/do/dooit/package.nix
@@ -0,0 +1,60 @@
+{ lib
+, fetchFromGitHub
+, dooit
+, python3
+, testers
+, nix-update-script
+}:
+
+python3.pkgs.buildPythonApplication rec {
+  pname = "dooit";
+  version = "2.2.0";
+  pyproject = true;
+
+  src = fetchFromGitHub {
+    owner = "kraanzu";
+    repo = "dooit";
+    rev = "v${version}";
+    hash = "sha256-GtXRzj+o+FClleh73kqelk0JrSyafZhf847lX1BiS9k=";
+  };
+
+  nativeBuildInputs = with python3.pkgs; [
+    poetry-core
+    pythonRelaxDepsHook
+  ];
+
+  pythonRelaxDeps = [
+    "textual"
+    "tzlocal"
+  ];
+
+  propagatedBuildInputs = with python3.pkgs; [
+    appdirs
+    pyperclip
+    python-dateutil
+    pyyaml
+    textual
+    tzlocal
+  ];
+
+  # No tests available
+  doCheck = false;
+
+  passthru = {
+    tests.version = testers.testVersion {
+      package = dooit;
+      command = "HOME=$(mktemp -d) dooit --version";
+    };
+
+    updateScript = nix-update-script { };
+  };
+
+  meta = with lib; {
+    description = "A TUI todo manager";
+    homepage = "https://github.com/kraanzu/dooit";
+    changelog = "https://github.com/kraanzu/dooit/blob/v${version}/CHANGELOG.md";
+    license = licenses.mit;
+    maintainers = with maintainers; [ khaneliman wesleyjrz ];
+    mainProgram = "dooit";
+  };
+}