Merge pull request #264555 from adtya/smc/chilanka/init

smc-chilanka: init at 1.7

1 files changed, 39 insertions, 0 deletions

diff --git a/pkgs/data/fonts/smc-chilanka/default.nix b/pkgs/data/fonts/smc-chilanka/default.nix
new file mode 100644
index 0000000000000..f5e5ee2cb5d87
--- /dev/null
+++ b/pkgs/data/fonts/smc-chilanka/default.nix
@@ -0,0 +1,39 @@
+{ lib, stdenvNoCC, fetchFromGitLab, python3Packages, gnumake, truetype ? false }:
+
+stdenvNoCC.mkDerivation rec {
+  pname = "chilanka";
+  version = "1.7";
+
+  src = fetchFromGitLab {
+    group = "smc";
+    owner = "fonts";
+    repo = "chilanka";
+    rev = "Version${version}";
+    hash = "sha256-VvotRUQks8vUqJOcYHqy6cuwaAKYg4OqtiAjaBIdBRk=";
+  };
+
+  nativeBuildInputs = [ gnumake python3Packages.fontmake ];
+
+  buildFlags = [ "otf" ] ++ lib.optional truetype "ttf";
+
+  installPhase = ''
+    runHook preInstall
+
+    install -Dm444 -t $out/share/fonts/opentype build/*.otf
+    ${lib.optionalString truetype "install -Dm444 -t $out/share/fonts/truetype build/*.ttf"}
+
+    install -Dm444 -t $out/etc/fonts/conf.d *.conf
+
+    install -Dm644 -t $out/share/doc/${pname}-${version} OFL.txt FONTLOG.md
+
+    runHook postInstall
+  '';
+
+  meta = with lib; {
+    homepage = "https://smc.org.in/fonts/chilanka";
+    description = "Chilanka Malayalam Typeface";
+    license = licenses.ofl;
+    platforms = platforms.all;
+    maintainers = with maintainers; [ adtya ];
+  };
+}