python3Packages.energyflow: init at 1.3.2

1 files changed, 54 insertions, 0 deletions

diff --git a/pkgs/development/python-modules/energyflow/default.nix b/pkgs/development/python-modules/energyflow/default.nix
new file mode 100644
index 0000000000000..44342d732eca9
--- /dev/null
+++ b/pkgs/development/python-modules/energyflow/default.nix
@@ -0,0 +1,54 @@
+{ lib
+, buildPythonPackage
+, fetchFromGitHub
+, h5py
+, numpy
+, six
+, wasserstein
+, pytestCheckHook
+}:
+
+buildPythonPackage rec {
+  pname = "EnergyFlow";
+  version = "1.3.2";
+
+  src = fetchFromGitHub {
+    owner = "pkomiske";
+    repo = pname;
+    rev = "v${version}";
+    hash = "sha256-fjT8c0ZTjdufP334upPzRVdTJDIBs84I7PkFu4CMcQw=";
+  };
+
+  postPatch = ''
+    substituteInPlace setup.cfg \
+      --replace "setup_requires=" "" \
+      --replace "pytest-runner" ""
+  '';
+
+  propagatedBuildInputs = [
+    h5py
+    numpy
+    six
+    wasserstein
+  ];
+
+  checkInputs = [
+    pytestCheckHook
+  ];
+  pytestFlagsArray = [
+    "energyflow/tests"
+  ];
+  disabledTestPaths = [
+    "energyflow/tests/test_archs.py" # requires tensorflow
+    "energyflow/tests/test_emd.py" # requires "ot"
+  ];
+
+  pythonImportsCheck = [ "energyflow" ];
+
+  meta = with lib; {
+    description = "Python package for the EnergyFlow suite of tools";
+    homepage = "https://energyflow.network/";
+    license = licenses.gpl3Only;
+    maintainers = with maintainers; [ veprbl ];
+  };
+}