pulumiPackages.pulumi-language-python: init at 3.43.1

2 files changed, 46 insertions, 0 deletions

diff --git a/pkgs/tools/admin/pulumi-packages/default.nix b/pkgs/tools/admin/pulumi-packages/default.nix
index 57cb7ad9061e1..6c732fec6c731 100644
--- a/pkgs/tools/admin/pulumi-packages/default.nix
+++ b/pkgs/tools/admin/pulumi-packages/default.nix
@@ -4,5 +4,6 @@ let
   callPackage' = p: args: callPackage p (args // { inherit mkPulumiPackage; });
 in
 {
+  pulumi-language-python = callPackage ./pulumi-language-python.nix { };
   pulumi-random = callPackage' ./pulumi-random.nix { };
 }
diff --git a/pkgs/tools/admin/pulumi-packages/pulumi-language-python.nix b/pkgs/tools/admin/pulumi-packages/pulumi-language-python.nix
new file mode 100644
index 0000000000000..658755fcf2f8f
--- /dev/null
+++ b/pkgs/tools/admin/pulumi-packages/pulumi-language-python.nix
@@ -0,0 +1,45 @@
+{ lib
+, buildGoModule
+, pulumi
+, python3
+}:
+buildGoModule rec {
+  inherit (pulumi) version src;
+
+  pname = "pulumi-language-python";
+
+  sourceRoot = "${src.name}/sdk";
+
+  vendorHash = "sha256-IZIdLmNGMFjRdkLPoE9UyON3pX/GBIgz/rv108v8iLY=";
+
+  postPatch = ''
+    # Requires network
+    substituteInPlace python/python_test.go \
+      --replace "TestRunningPipInVirtualEnvironment" \
+                "SkipTestRunningPipInVirtualEnvironment"
+
+    substituteInPlace python/cmd/pulumi-language-python/main_test.go \
+      --replace "TestDeterminePulumiPackages" \
+                "SkipTestDeterminePulumiPackages"
+  '';
+
+  subPackages = [
+    "python/cmd/pulumi-language-python"
+  ];
+
+  ldflags = [
+    "-s"
+    "-w"
+    "-X github.com/pulumi/pulumi/sdk/v3/go/common/version.Version=${version}"
+  ];
+
+  checkInputs = [
+    python3
+  ];
+
+  postInstall = ''
+    cp python/cmd/pulumi-language-python-exec    $out/bin
+    cp python/dist/pulumi-resource-pulumi-python $out/bin
+    cp python/dist/pulumi-analyzer-policy-python $out/bin
+  '';
+}