Move ibus packages to the inputmethods directory.

2 files changed, 67 insertions, 0 deletions

diff --git a/pkgs/tools/inputmethods/ibus-qt/default.nix b/pkgs/tools/inputmethods/ibus-qt/default.nix
new file mode 100644
index 0000000000000..c538d36ec591f
--- /dev/null
+++ b/pkgs/tools/inputmethods/ibus-qt/default.nix
@@ -0,0 +1,25 @@
+{ stdenv, fetchurl, ibus, cmake, pkgconfig, qt4, icu, doxygen }:
+
+stdenv.mkDerivation rec {
+  name = "ibus-qt-${version}";
+  version = "1.3.2";
+
+  src = fetchurl {
+    url = "http://ibus.googlecode.com/files/${name}-Source.tar.gz";
+    sha256 = "070c8ef4e6c74eddf7ddf4385936aed730c2dfe2160162e5c56b5158d1061a76";
+  };
+
+  buildInputs = [
+    ibus cmake pkgconfig qt4 icu doxygen
+  ];
+
+  cmakeFlags = [ "-DQT_PLUGINS_DIR=lib/qt4/plugins" ];
+
+  meta = with stdenv.lib; {
+    homepage    = https://code.google.com/p/ibus/;
+    description = "Qt4 interface to the ibus input method";
+    platforms   = platforms.linux;
+    license     = licenses.gpl2Plus;
+    maintainers = with maintainers; [ gebner ];
+  };
+}
diff --git a/pkgs/tools/inputmethods/ibus/default.nix b/pkgs/tools/inputmethods/ibus/default.nix
new file mode 100644
index 0000000000000..6b426169a708e
--- /dev/null
+++ b/pkgs/tools/inputmethods/ibus/default.nix
@@ -0,0 +1,42 @@
+{ stdenv, fetchurl, makeWrapper, python, intltool, pkgconfig
+, gnome3, atk, pygobject3, dbus, libnotify, isocodes, gobjectIntrospection, wayland }:
+
+stdenv.mkDerivation rec {
+  name = "ibus-${version}";
+  version = "1.5.5";
+
+  src = fetchurl {
+    url = "http://ibus.googlecode.com/files/${name}.tar.gz";
+    sha256 = "1v4a9xv2k26g6ggk4282ynfvh68j2r5hg1cdpvnryfa8c2pkdaq2";
+  };
+
+  configureFlags = "--disable-gconf --enable-dconf --disable-memconf --enable-ui --enable-python-library";
+
+  buildInputs = [
+    makeWrapper python gnome3.glib wayland
+    intltool pkgconfig gnome3.gtk2
+    gnome3.gtk3 dbus gnome3.dconf gnome3.gconf
+    libnotify isocodes gobjectIntrospection
+  ];
+
+  preBuild = ''
+    patchShebangs ./scripts
+    substituteInPlace data/dconf/Makefile --replace "dconf update" "echo"
+  '';
+
+  preFixup = ''
+    for f in "$out"/bin/*; do
+      wrapProgram "$f" --prefix XDG_DATA_DIRS : "$out/share:$GSETTINGS_SCHEMAS_PATH" \
+                       --prefix PYTHONPATH : "$(toPythonPath ${pygobject3})" \
+                       --prefix LD_LIBRARY_PATH : "${gnome3.gtk3}/lib:${atk}/lib:$out/lib" \
+                       --prefix GI_TYPELIB_PATH : "$GI_TYPELIB_PATH:$out/lib/girepository-1.0" \
+                       --prefix GIO_EXTRA_MODULES : "${gnome3.dconf}/lib/gio/modules"
+    done
+  '';
+
+  meta = {
+    homepage = https://code.google.com/p/ibus/;
+    description = "Intelligent Input Bus for Linux / Unix OS";
+    platforms = stdenv.lib.platforms.linux;
+  };
+}