1 files changed, 48 insertions, 0 deletions
diff --git a/pkgs/by-name/ch/choose-gui/package.nix b/pkgs/by-name/ch/choose-gui/package.nix
new file mode 100644
index 0000000000000..bbf1ff2a8578c
--- /dev/null
+++ b/pkgs/by-name/ch/choose-gui/package.nix
@@ -0,0 +1,48 @@
+{
+  lib,
+  stdenv,
+  fetchFromGitHub,
+  xcbuild,
+  darwin,
+}:
+
+stdenv.mkDerivation rec {
+  pname = "choose-gui";
+  version = "1.3.1";
+
+  src = fetchFromGitHub {
+    owner = "chipsenkbeil";
+    repo = "choose";
+    rev = version;
+    hash = "sha256-oR0GgMinKcBHaZWdE7O+mdbiLKKjkweECKbi80bjW+c=";
+  };
+
+  nativeBuildInputs = [ xcbuild ];
+
+  buildInputs = [ darwin.apple_sdk.frameworks.Cocoa ];
+
+  buildPhase = ''
+    runHook preBuild
+    xcodebuild -arch ${stdenv.hostPlatform.darwinArch} -configuration Release SYMROOT="./output" build
+    cp ./output/Release/choose choose
+    runHook postBuild
+  '';
+
+  installPhase = ''
+    runHook preInstall
+    mkdir -p $out/bin
+    cp choose $out/bin/choose
+    chmod +x $out/bin/choose
+    runHook postInstall
+  '';
+
+  meta = {
+    description = "Fuzzy matcher for OS X that uses both std{in,out} and a native GUI";
+    homepage = "https://github.com/chipsenkbeil/choose";
+    license = lib.licenses.mit;
+    platforms = lib.platforms.darwin;
+    changelog = "https://github.com/chipsenkbeil/choose/blob/${version}/CHANGELOG.md";
+    maintainers = with lib.maintainers; [ heywoodlh ];
+    mainProgram = "choose";
+  };
+}