1 files changed, 65 insertions, 0 deletions
diff --git a/pkgs/by-name/sd/SDL2_ttf/package.nix b/pkgs/by-name/sd/SDL2_ttf/package.nix
new file mode 100644
index 0000000000000..b4cda24402377
--- /dev/null
+++ b/pkgs/by-name/sd/SDL2_ttf/package.nix
@@ -0,0 +1,65 @@
+{
+  lib,
+  SDL2,
+  darwin,
+  fetchurl,
+  freetype,
+  harfbuzz,
+  libGL,
+  pkg-config,
+  stdenv,
+  testers,
+  # Boolean flags
+  enableSdltest ? (!stdenv.isDarwin),
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "SDL2_ttf";
+  version = "2.22.0";
+
+  src = fetchurl {
+    url = "https://www.libsdl.org/projects/SDL_ttf/release/SDL2_ttf-${finalAttrs.version}.tar.gz";
+    sha256 = "sha256-1Iy9HOR1ueF4IGvzty1Wtm2E1E9krAWAMyg5YjTWdyM=";
+  };
+
+  nativeBuildInputs = [
+    SDL2
+    pkg-config
+  ];
+
+  buildInputs = [
+    SDL2
+    freetype
+    harfbuzz
+  ]
+  ++ lib.optionals (!stdenv.isDarwin) [
+    libGL
+  ]
+  ++ lib.optionals stdenv.isDarwin [
+    darwin.libobjc
+  ];
+
+  configureFlags = [
+    (lib.enableFeature false "harfbuzz-builtin")
+    (lib.enableFeature false "freetype-builtin")
+    (lib.enableFeature enableSdltest "sdltest")
+  ];
+
+  strictDeps = true;
+
+  passthru = {
+    tests.pkg-config = testers.hasPkgConfigModules {
+      package = finalAttrs.finalPackage;
+    };
+  };
+
+  meta = {
+    homepage = "https://github.com/libsdl-org/SDL_ttf";
+    description = "Support for TrueType (.ttf) font files with Simple Directmedia Layer";
+    license = lib.licenses.zlib;
+    maintainers = lib.teams.sdl.members
+                  ++ (with lib.maintainers; [ ]);
+    inherit (SDL2.meta) platforms;
+    pkgConfigModules = [ "SDL2_ttf" ];
+  };
+})