about summary refs log tree commit diff
path: root/pkgs/by-name
diff options
context:
space:
mode:
Diffstat (limited to 'pkgs/by-name')
-rw-r--r--pkgs/by-name/al/aligator/package.nix97
-rw-r--r--pkgs/by-name/cr/crocoddyl/package.nix89
-rw-r--r--pkgs/by-name/ei/eiquadprog/package.nix10
-rw-r--r--pkgs/by-name/ex/example-robot-data/package.nix74
-rw-r--r--pkgs/by-name/hp/hpp-fcl/package.nix20
-rw-r--r--pkgs/by-name/jr/jrl-cmakemodules/package.nix7
-rw-r--r--pkgs/by-name/pi/pinocchio/package.nix119
-rw-r--r--pkgs/by-name/pr/proxsuite-nlp/package.nix16
-rw-r--r--pkgs/by-name/pr/proxsuite/package.nix52
-rw-r--r--pkgs/by-name/ts/tsid/package.nix24
10 files changed, 442 insertions, 66 deletions
diff --git a/pkgs/by-name/al/aligator/package.nix b/pkgs/by-name/al/aligator/package.nix
new file mode 100644
index 000000000000..53346434be78
--- /dev/null
+++ b/pkgs/by-name/al/aligator/package.nix
@@ -0,0 +1,97 @@
+{
+  cmake,
+  crocoddyl,
+  doxygen,
+  fetchFromGitHub,
+  fmt,
+  fontconfig,
+  gbenchmark,
+  graphviz,
+  lib,
+  llvmPackages, # llvm/Support/Host.h required by casadi 3.6.5 and not available in llvm 18
+  pinocchio,
+  pkg-config,
+  proxsuite-nlp,
+  python3Packages,
+  pythonSupport ? false,
+  stdenv,
+  suitesparse,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "aligator";
+  version = "0.8.0";
+
+  src = fetchFromGitHub {
+    owner = "Simple-Robotics";
+    repo = "aligator";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-o4QjxTaZUa17hZsCv4hCI2cedaHoojBtLe8SVUkl0bo=";
+  };
+
+  outputs = [
+    "doc"
+    "out"
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs = [
+    doxygen
+    cmake
+    graphviz
+    pkg-config
+  ] ++ lib.optional pythonSupport python3Packages.pythonImportsCheckHook;
+  buildInputs = [ fmt ] ++ lib.optional stdenv.isDarwin llvmPackages.openmp;
+  propagatedBuildInputs =
+    [ suitesparse ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.crocoddyl
+      python3Packages.matplotlib
+      python3Packages.pinocchio
+      python3Packages.proxsuite-nlp
+    ]
+    ++ lib.optionals (!pythonSupport) [
+      crocoddyl
+      pinocchio
+      proxsuite-nlp
+    ];
+  checkInputs =
+    [ gbenchmark ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.matplotlib
+      python3Packages.pytest
+    ];
+
+  cmakeFlags =
+    [
+      (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
+      (lib.cmakeBool "BUILD_WITH_PINOCCHIO_SUPPORT" true)
+      (lib.cmakeBool "BUILD_CROCODDYL_COMPAT" true)
+      (lib.cmakeBool "BUILD_WITH_OPENMP_SUPPORT" true)
+      (lib.cmakeBool "BUILD_WITH_CHOLMOD_SUPPORT" true)
+      (lib.cmakeBool "GENERATE_PYTHON_STUBS" false) # this need git at configure time
+    ]
+    ++ lib.optionals (stdenv.hostPlatform.isDarwin && pythonSupport) [
+      # ignore one failing test for now
+      (lib.cmakeFeature "CMAKE_CTEST_ARGUMENTS" "--exclude-regex;aligator-test-py-integrators")
+    ];
+
+  # Fontconfig error: Cannot load default config file: No such file: (null)
+  env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
+
+  # Fontconfig error: No writable cache directories
+  preBuild = "export XDG_CACHE_HOME=$(mktemp -d)";
+
+  doCheck = true;
+  pythonImportsCheck = [ "aligator" ];
+
+  meta = {
+    description = "Versatile and efficient framework for constrained trajectory optimization";
+    homepage = "https://github.com/Simple-Robotics/aligator";
+    changelog = "https://github.com/Simple-Robotics/aligator/blob/v${finalAttrs.version}/CHANGELOG.md";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.unix;
+  };
+})
diff --git a/pkgs/by-name/cr/crocoddyl/package.nix b/pkgs/by-name/cr/crocoddyl/package.nix
new file mode 100644
index 000000000000..a1a283727743
--- /dev/null
+++ b/pkgs/by-name/cr/crocoddyl/package.nix
@@ -0,0 +1,89 @@
+{
+  blas,
+  cmake,
+  doxygen,
+  example-robot-data,
+  fetchFromGitHub,
+  ipopt,
+  lapack,
+  lib,
+  pinocchio,
+  pkg-config,
+  pythonSupport ? false,
+  python3Packages,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "crocoddyl";
+  version = "2.1.0";
+
+  src = fetchFromGitHub {
+    owner = "loco-3d";
+    repo = "crocoddyl";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-SVV9sleDXLm2QJmNgL25XLHC3y5bfKab4GSlE8jbT8w=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+  ];
+
+  strictDeps = true;
+
+  nativeBuildInputs =
+    [
+      cmake
+      doxygen
+      pkg-config
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.python
+      python3Packages.pythonImportsCheckHook
+    ];
+
+  propagatedBuildInputs =
+    [
+      blas
+      ipopt
+      lapack
+    ]
+    ++ lib.optionals (!pythonSupport) [
+      example-robot-data
+      pinocchio
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.example-robot-data
+      python3Packages.pinocchio
+      python3Packages.scipy
+    ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "INSTALL_DOCUMENTATION" true)
+    (lib.cmakeBool "BUILD_EXAMPLES" pythonSupport)
+    (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
+  ];
+
+  prePatch = ''
+    substituteInPlace \
+      examples/CMakeLists.txt \
+      examples/log/check_logfiles.sh \
+      --replace-fail /bin/bash ${stdenv.shell}
+  '';
+
+  doCheck = true;
+  pythonImportsCheck = [ "crocoddyl" ];
+  checkInputs = lib.optionals pythonSupport [ python3Packages.scipy ];
+
+  meta = with lib; {
+    description = "Crocoddyl optimal control library";
+    homepage = "https://github.com/loco-3d/crocoddyl";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [
+      nim65s
+      wegank
+    ];
+    platforms = platforms.unix;
+  };
+})
diff --git a/pkgs/by-name/ei/eiquadprog/package.nix b/pkgs/by-name/ei/eiquadprog/package.nix
index 9380e7f9d2bf..70242a2aa9a0 100644
--- a/pkgs/by-name/ei/eiquadprog/package.nix
+++ b/pkgs/by-name/ei/eiquadprog/package.nix
@@ -1,10 +1,12 @@
 {
   boost,
   cmake,
+  doxygen,
   eigen,
   fetchFromGitHub,
   jrl-cmakemodules,
   lib,
+  pkg-config,
   stdenv,
 }:
 
@@ -19,8 +21,15 @@ stdenv.mkDerivation (finalAttrs: {
     hash = "sha256-VqRx06sCCZrnB+NWm6Z9OMKzjKQIydGgKQU6fMY7phk=";
   };
 
+  outputs = [
+    "out"
+    "doc"
+  ];
+
   nativeBuildInputs = [
     cmake
+    doxygen
+    pkg-config
     jrl-cmakemodules
   ];
   propagatedBuildInputs = [ eigen ];
@@ -34,5 +43,6 @@ stdenv.mkDerivation (finalAttrs: {
     changelog = "https://github.com/stack-of-tasks/eiquadprog/blob/v${finalAttrs.version}/CHANGELOG.md";
     license = lib.licenses.gpl3Only;
     maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.unix;
   };
 })
diff --git a/pkgs/by-name/ex/example-robot-data/package.nix b/pkgs/by-name/ex/example-robot-data/package.nix
new file mode 100644
index 000000000000..63331bbf5a84
--- /dev/null
+++ b/pkgs/by-name/ex/example-robot-data/package.nix
@@ -0,0 +1,74 @@
+{
+  cmake,
+  doxygen,
+  fetchFromGitHub,
+  fetchpatch,
+  lib,
+  pkg-config,
+  pythonSupport ? false,
+  python3Packages,
+  stdenv,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "example-robot-data";
+  version = "4.1.0";
+
+  src = fetchFromGitHub {
+    owner = "Gepetto";
+    repo = "example-robot-data";
+    rev = "v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-Heq+c8SSYNO8ksTv5FphRBRStlTakm9T66jlPXon5tI=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+  ];
+
+  strictDeps = true;
+
+  patches = [
+    # Temporary patch for pinocchio v3.0.0 compatibility.
+    # Should be removed on next example-robot-data release
+    (fetchpatch {
+      name = "pin3.patch";
+      url = "https://github.com/Gepetto/example-robot-data/pull/217/commits/a605ceec857005cde153ec5895e227205eb7a5c3.patch";
+      hash = "sha256-cvAWFytrU2XVggo/nCg8cuLcaZBTACXg6LxjL/6YMPs=";
+    })
+  ];
+
+  nativeBuildInputs =
+    [
+      cmake
+      doxygen
+      pkg-config
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.python
+      python3Packages.pythonImportsCheckHook
+    ];
+
+  propagatedBuildInputs = lib.optionals pythonSupport [ python3Packages.pinocchio ];
+
+  cmakeFlags = [ (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport) ];
+
+  doCheck = true;
+  # The package expect to find an `example-robot-data/robots` folder somewhere
+  # either in install prefix or in the sources
+  # where it can find the meshes for unit tests
+  preCheck = "ln -s source ../../${finalAttrs.pname}";
+  pythonImportsCheck = [ "example_robot_data" ];
+
+  meta = with lib; {
+    description = "Set of robot URDFs for benchmarking and developed examples";
+    homepage = "https://github.com/Gepetto/example-robot-data";
+    license = licenses.bsd3;
+    maintainers = with maintainers; [
+      nim65s
+      wegank
+    ];
+    platforms = platforms.unix;
+  };
+})
diff --git a/pkgs/by-name/hp/hpp-fcl/package.nix b/pkgs/by-name/hp/hpp-fcl/package.nix
index 78ce6456c301..80e715425034 100644
--- a/pkgs/by-name/hp/hpp-fcl/package.nix
+++ b/pkgs/by-name/hp/hpp-fcl/package.nix
@@ -28,10 +28,15 @@ stdenv.mkDerivation (finalAttrs: {
 
   strictDeps = true;
 
-  nativeBuildInputs = [
-    cmake
-    doxygen
-  ] ++ lib.optionals pythonSupport [ python3Packages.numpy ];
+  nativeBuildInputs =
+    [
+      cmake
+      doxygen
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.numpy
+      python3Packages.pythonImportsCheckHook
+    ];
 
   propagatedBuildInputs =
     [
@@ -56,11 +61,7 @@ stdenv.mkDerivation (finalAttrs: {
   ];
 
   doCheck = true;
-  # pythonImportsCheck, but in stdenv.mkDerivation
-  postInstall = lib.optionalString pythonSupport ''
-    PYTHONPATH=$out/${python3Packages.python.sitePackages}:$PYTHONPATH
-    python -c "import hppfcl"
-  '';
+  pythonImportsCheck = [ "hppfcl" ];
 
   outputs = [
     "dev"
@@ -77,5 +78,6 @@ stdenv.mkDerivation (finalAttrs: {
     homepage = "https://github.com/humanoid-path-planner/hpp-fcl";
     license = lib.licenses.bsd3;
     maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.unix;
   };
 })
diff --git a/pkgs/by-name/jr/jrl-cmakemodules/package.nix b/pkgs/by-name/jr/jrl-cmakemodules/package.nix
index 8dc01688de66..22c9bafe6425 100644
--- a/pkgs/by-name/jr/jrl-cmakemodules/package.nix
+++ b/pkgs/by-name/jr/jrl-cmakemodules/package.nix
@@ -7,13 +7,13 @@
 
 stdenv.mkDerivation {
   pname = "jrl-cmakemodules";
-  version = "0-unstable-2024-08-05";
+  version = "0-unstable-2024-09-17";
 
   src = fetchFromGitHub {
     owner = "jrl-umi3218";
     repo = "jrl-cmakemodules";
-    rev = "88d3cb561d1f9faa3c6281da7b2b8d6aa76b04d5";
-    hash = "sha256-3Su/tGtV39/tto1Hs5sgGgjpFWkBCvI2SZKqBIIDAjA=";
+    rev = "31e46019beda968ba9e516ad645a951c64256eed";
+    hash = "sha256-pe21tE0ngUYGhEuGSI71TMdwyqTmZhc53hPKHngkTGQ=";
   };
 
   nativeBuildInputs = [ cmake ];
@@ -23,5 +23,6 @@ stdenv.mkDerivation {
     homepage = "https://github.com/jrl-umi3218/jrl-cmakemodules";
     license = lib.licenses.lgpl3Plus;
     maintainers = [ lib.maintainers.nim65s ];
+    platforms = lib.platforms.all;
   };
 }
diff --git a/pkgs/by-name/pi/pinocchio/package.nix b/pkgs/by-name/pi/pinocchio/package.nix
new file mode 100644
index 000000000000..e754078a3805
--- /dev/null
+++ b/pkgs/by-name/pi/pinocchio/package.nix
@@ -0,0 +1,119 @@
+{
+  boost,
+  casadi,
+  casadiSupport ? true,
+  cmake,
+  collisionSupport ? true,
+  console-bridge,
+  doxygen,
+  eigen,
+  example-robot-data,
+  fetchFromGitHub,
+  hpp-fcl,
+  jrl-cmakemodules,
+  lib,
+  pkg-config,
+  pythonSupport ? false,
+  python3Packages,
+  stdenv,
+  urdfdom,
+}:
+
+stdenv.mkDerivation (finalAttrs: {
+  pname = "pinocchio";
+  version = "3.2.0";
+
+  src = fetchFromGitHub {
+    owner = "stack-of-tasks";
+    repo = "pinocchio";
+    rev = "v${finalAttrs.version}";
+    hash = "sha256-8V+n1TwFojXKOVkGG8k9aXVadt2NBFlZKba93L+NRNU=";
+  };
+
+  outputs = [
+    "out"
+    "doc"
+  ];
+
+  # test failure, ref https://github.com/stack-of-tasks/pinocchio/issues/2277
+  prePatch = lib.optionalString (stdenv.isLinux && stdenv.isAarch64) ''
+    substituteInPlace unittest/algorithm/utils/CMakeLists.txt \
+      --replace-fail "add_pinocchio_unit_test(force)" ""
+  '';
+
+  postPatch = ''
+    # example-robot-data models are used in checks.
+    # Upstream provide them as git submodule, but we can use our own version instead.
+    test -d models/example-robot-data && rmdir models/example-robot-data
+    ln -s ${example-robot-data.src} models/example-robot-data
+
+    # allow package:// uri use in examples
+    export ROS_PACKAGE_PATH=${example-robot-data}/share
+
+    # silence matplotlib warning
+    export MPLCONFIGDIR=$(mktemp -d)
+  '';
+
+  # CMAKE_BUILD_TYPE defaults to Release in this package,
+  # which enable -O3, which break some tests
+  # ref. https://github.com/stack-of-tasks/pinocchio/issues/2304#issuecomment-2231018300
+  postConfigure = ''
+    substituteInPlace CMakeCache.txt --replace-fail '-O3' '-O2'
+  '';
+
+  strictDeps = true;
+
+  nativeBuildInputs =
+    [
+      cmake
+      doxygen
+      pkg-config
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.python
+      python3Packages.pythonImportsCheckHook
+    ];
+
+  propagatedBuildInputs =
+    [
+      console-bridge
+      jrl-cmakemodules
+      urdfdom
+    ]
+    ++ lib.optionals (!pythonSupport) [
+      boost
+      eigen
+    ]
+    ++ lib.optionals (!pythonSupport && collisionSupport) [ hpp-fcl ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.boost
+      python3Packages.eigenpy
+    ]
+    ++ lib.optionals (pythonSupport && collisionSupport) [ python3Packages.hpp-fcl ]
+    ++ lib.optionals (!pythonSupport && casadiSupport) [ casadi ]
+    ++ lib.optionals (pythonSupport && casadiSupport) [ python3Packages.casadi ];
+
+  checkInputs = lib.optionals (pythonSupport && casadiSupport) [ python3Packages.matplotlib ];
+
+  cmakeFlags = [
+    (lib.cmakeBool "BUILD_PYTHON_INTERFACE" pythonSupport)
+    (lib.cmakeBool "BUILD_WITH_LIBPYTHON" pythonSupport)
+    (lib.cmakeBool "BUILD_WITH_CASADI_SUPPORT" casadiSupport)
+    (lib.cmakeBool "BUILD_WITH_COLLISION_SUPPORT" collisionSupport)
+    (lib.cmakeBool "INSTALL_DOCUMENTATION" true)
+  ];
+
+  doCheck = true;
+  pythonImportsCheck = [ "pinocchio" ];
+
+  meta = {
+    description = "Fast and flexible implementation of Rigid Body Dynamics algorithms and their analytical derivatives";
+    homepage = "https://github.com/stack-of-tasks/pinocchio";
+    license = lib.licenses.bsd2;
+    maintainers = with lib.maintainers; [
+      nim65s
+      wegank
+    ];
+    platforms = lib.platforms.unix;
+  };
+})
diff --git a/pkgs/by-name/pr/proxsuite-nlp/package.nix b/pkgs/by-name/pr/proxsuite-nlp/package.nix
index 234cc93febc7..194ff2fe967d 100644
--- a/pkgs/by-name/pr/proxsuite-nlp/package.nix
+++ b/pkgs/by-name/pr/proxsuite-nlp/package.nix
@@ -19,32 +19,26 @@
 
 stdenv.mkDerivation (finalAttrs: {
   pname = "proxsuite-nlp";
-  version = "0.7.1";
+  version = "0.8.0";
 
   src = fetchFromGitHub {
     owner = "Simple-Robotics";
     repo = "proxsuite-nlp";
     rev = "v${finalAttrs.version}";
-    hash = "sha256-aMTEjAu1ltjorx5vhz7klB0cGgdm+7STAPhi+NA6mnI=";
+    hash = "sha256-Dy8+pPTv/B6vVdpGndVOV16WSLiENJfaIrn1+FYwcI0=";
   };
 
   outputs = [
-    "doc"
     "out"
+    "doc"
   ];
 
   patches = [
     # Fix use of system jrl-cmakemodules
     # This patch was merged upstream and can be removed on next release
     (fetchpatch {
-      url = "https://github.com/Simple-Robotics/proxsuite-nlp/pull/106/commits/c653ab67860fdf7b53b1a919f0b8a7746eba016b.patch";
-      hash = "sha256-Kw2obJGOWms/Lr4cVkLFpaLTickCq5WQyDVbwi8Bd58=";
-    })
-    # Fix use of system EigenRand
-    # This patch was merged upstream and can be removed on next release
-    (fetchpatch {
-      url = "https://github.com/Simple-Robotics/proxsuite-nlp/pull/106/commits/25370417755f003708b5b2b81e253797e8d96928.patch";
-      hash = "sha256-PKijVmttt5JakF3X/GiVWptncxHJUbs/aikgwgB5NME=";
+      url = "https://github.com/Simple-Robotics/proxsuite-nlp/pull/109/commits/9bf741ce6010052a773071472891f42adc6cbbea.patch";
+      hash = "sha256-sluMVrTw7EXLFa0dqkoZTkpGjKe7zODqIqbJxCdfSwY=";
     })
   ];
 
diff --git a/pkgs/by-name/pr/proxsuite/package.nix b/pkgs/by-name/pr/proxsuite/package.nix
index dcaf8bc6f7f2..6aba0e20c76e 100644
--- a/pkgs/by-name/pr/proxsuite/package.nix
+++ b/pkgs/by-name/pr/proxsuite/package.nix
@@ -3,10 +3,12 @@
   stdenv,
   fetchFromGitHub,
   fetchpatch,
-  cereal,
+  cereal_1_3_2,
   cmake,
   doxygen,
   eigen,
+  fontconfig,
+  graphviz,
   jrl-cmakemodules,
   simde,
   matio,
@@ -15,47 +17,24 @@
 }:
 stdenv.mkDerivation (finalAttrs: {
   pname = "proxsuite";
-  version = "0.6.6";
+  version = "0.6.7";
 
   src = fetchFromGitHub {
     owner = "simple-robotics";
     repo = "proxsuite";
     rev = "v${finalAttrs.version}";
-    hash = "sha256-3kzFYADk3sCMU827KowilPlmOqgv69DJ3mOb7623Qdg=";
+    hash = "sha256-iKc55WDHArmmIM//Wir6FHrNV84HnEDcBUlwnsbtMME=";
   };
 
   patches = [
-    # Allow use of system jrl-cmakemodules
-    # This was merged upstream, and can be removed on next release
+    # Fix use of system cereal
+    # This was merged upstream and can be removed on next release
     (fetchpatch {
-      url = "https://github.com/Simple-Robotics/proxsuite/pull/334/commits/2bcadd4993a9940c545136faa71bf1e97a972735.patch";
-      hash = "sha256-BPtwogSwSXcEd5FM4eTTCq6LpGWvQ1SOCFmv/GVhl18=";
-    })
-    # Allow use of system cereal
-    # This was merged upstream, and can be removed on next release
-    (fetchpatch {
-      url = "https://github.com/Simple-Robotics/proxsuite/pull/334/commits/878337c6284c9fd73b19f1f80d5fa802def8cdc6.patch";
-      hash = "sha256-+HWYHLGtygjlvjM+FSD9WFDIwO+qPLlzci+7q42bo0I=";
-    })
-    # Allow use of system pybind11
-    # upstream will move to nanobind for next release, so this can be dismissed
-    (fetchpatch {
-      url = "https://github.com/Simple-Robotics/proxsuite/pull/337/commits/bbed9bdfb214da7c6c6909582971bd8b877f87c2.patch";
-      hash = "sha256-pYikPZinjmk7gsagiaIcQspmGFYwlhdiKdZPnqo7pcQ=";
+      url = "https://github.com/Simple-Robotics/proxsuite/pull/352/commits/8305864f13ca7dff7210f89004a56652b71f8891.patch";
+      hash = "sha256-XMS/zHFVrEp1P6aDlGrLbrcmuKq42+GdZRH9ObewNCY=";
     })
   ];
 
-  postPatch = ''
-    # discard failing tests for now
-    substituteInPlace test/CMakeLists.txt \
-      --replace-fail "proxsuite_test(dense_maros_meszaros src/dense_maros_meszaros.cpp)" "" \
-      --replace-fail "proxsuite_test(sparse_maros_meszaros src/sparse_maros_meszaros.cpp)" ""
-
-    # fix CMake syntax
-    substituteInPlace bindings/python/CMakeLists.txt \
-      --replace-fail "SYSTEM PRIVATE" "PRIVATE"
-  '';
-
   outputs = [
     "doc"
     "out"
@@ -76,9 +55,10 @@ stdenv.mkDerivation (finalAttrs: {
   nativeBuildInputs = [
     cmake
     doxygen
-  ];
+    graphviz
+  ] ++ lib.optional pythonSupport python3Packages.pythonImportsCheckHook;
   propagatedBuildInputs = [
-    cereal
+    cereal_1_3_2
     eigen
     jrl-cmakemodules
     simde
@@ -90,12 +70,20 @@ stdenv.mkDerivation (finalAttrs: {
       python3Packages.scipy
     ];
 
+  # Fontconfig error: Cannot load default config file: No such file: (null)
+  env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
+
+  # Fontconfig error: No writable cache directories
+  preBuild = "export XDG_CACHE_HOME=$(mktemp -d)";
+
   doCheck = true;
+  pythonImportsCheck = [ "proxsuite" ];
 
   meta = {
     description = "The Advanced Proximal Optimization Toolbox";
     homepage = "https://github.com/Simple-Robotics/proxsuite";
     license = lib.licenses.bsd2;
     maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.unix;
   };
 })
diff --git a/pkgs/by-name/ts/tsid/package.nix b/pkgs/by-name/ts/tsid/package.nix
index 054857f8b222..0bd4b08b6025 100644
--- a/pkgs/by-name/ts/tsid/package.nix
+++ b/pkgs/by-name/ts/tsid/package.nix
@@ -32,15 +32,20 @@ stdenv.mkDerivation (finalAttrs: {
   ];
 
   outputs = [
-    "doc"
     "out"
+    "doc"
   ];
 
-  nativeBuildInputs = [
-    doxygen
-    cmake
-    pkg-config
-  ] ++ lib.optional pythonSupport python3Packages.python;
+  nativeBuildInputs =
+    [
+      doxygen
+      cmake
+      pkg-config
+    ]
+    ++ lib.optionals pythonSupport [
+      python3Packages.python
+      python3Packages.pythonImportsCheckHook
+    ];
 
   propagatedBuildInputs =
     [
@@ -51,16 +56,13 @@ stdenv.mkDerivation (finalAttrs: {
     ++ lib.optional (!pythonSupport) pinocchio ++ lib.optional pythonSupport python3Packages.pinocchio;
 
   doCheck = true;
-  # pythonImportsCheck, but in stdenv.mkDerivation
-  postInstall = lib.optionalString pythonSupport ''
-    PYTHONPATH=$out/${python3Packages.python.sitePackages}:$PYTHONPATH
-    python -c "import tsid"
-  '';
+  pythonImportsCheck = [ "tsid" ];
 
   meta = {
     description = "Efficient Task Space Inverse Dynamics (TSID) based on Pinocchio";
     homepage = "https://github.com/stack-of-tasks/tsid";
     license = lib.licenses.bsd2;
     maintainers = with lib.maintainers; [ nim65s ];
+    platforms = lib.platforms.unix;
   };
 })
generated by cgit-pink 1.4.1 (git 2.36.1) at 2024-11-15 16:50:35 +0000