1 files changed, 38 insertions, 0 deletions
diff --git a/pkgs/data/themes/sddm-astronaut/default.nix b/pkgs/data/themes/sddm-astronaut/default.nix
new file mode 100644
index 0000000000000..ef8071f1e858e
--- /dev/null
+++ b/pkgs/data/themes/sddm-astronaut/default.nix
@@ -0,0 +1,38 @@
+{ pkgs, lib, stdenvNoCC, themeConfig ? null }:
+stdenvNoCC.mkDerivation rec {
+  pname = "sddm-astronaut";
+  version = "1.0";
+
+  src = pkgs.fetchFromGitHub {
+    owner = "Keyitdev";
+    repo = "sddm-astronaut-theme";
+    rev = "48ea0a792711ac0c58cc74f7a03e2e7ba3dc2ac0";
+    hash = "sha256-kXovz813BS+Mtbk6+nNNdnluwp/7V2e3KJLuIfiWRD0=";
+  };
+
+  dontWrapQtApps = true;
+  propagatedBuildInputs = with pkgs.kdePackages; [ qt5compat qtsvg ];
+
+  installPhase =
+    let
+      iniFormat = pkgs.formats.ini { };
+      configFile = iniFormat.generate "" { General = themeConfig; };
+
+      basePath = "$out/share/sddm/themes/sddm-astronaut-theme";
+    in
+    ''
+      mkdir -p ${basePath}
+      cp -r $src/* ${basePath}
+    '' + lib.optionalString (themeConfig != null) ''
+      ln -sf ${configFile} ${basePath}/theme.conf.user
+    '';
+
+  meta = {
+    description = "Modern looking qt6 sddm theme";
+    homepage = "https://github.com/${src.owner}/${pname}";
+    license = lib.licenses.gpl3;
+
+    platforms = lib.platforms.linux;
+    maintainers = with lib.maintainers; [ danid3v ];
+  };
+}