1 files changed, 61 insertions, 0 deletions
diff --git a/pkgs/development/libraries/dbus/1.5.6.nix b/pkgs/development/libraries/dbus/1.5.6.nix
new file mode 100644
index 0000000000000..a5ba03159f1c3
--- /dev/null
+++ b/pkgs/development/libraries/dbus/1.5.6.nix
@@ -0,0 +1,61 @@
+{ stdenv, fetchurl, pkgconfig, expat, libX11, libICE, libSM, useX11 ? true }:
+
+let
+  version = "1.5.6";
+
+  src = fetchurl {
+    url = "http://dbus.freedesktop.org/releases/dbus/dbus-${version}.tar.gz";
+    sha256 = "18g5328wnh25p0hihv5gg55q5l019zzwr04shvp67myvwy07m851";
+  };
+
+  patches = [ ./ignore-missing-includedirs.patch ];
+
+  configureFlags = "--localstatedir=/var --sysconfdir=/etc --with-session-socket-dir=/tmp";
+
+in rec {
+
+  libs = stdenv.mkDerivation {
+    name = "dbus-library-" + version;
+
+    buildInputs = [ pkgconfig expat ];
+
+    inherit src patches configureFlags;
+
+    preConfigure =
+      ''
+        sed -i '/mkinstalldirs.*localstatedir/d' bus/Makefile.in
+        sed -i '/SUBDIRS/s/ tools//' Makefile.in
+      '';
+
+    # Enable X11 autolaunch support in libdbus.  This doesn't actually
+    # depend on X11 (it just execs dbus-launch in dbus.tools),
+    # contrary to what the configure script demands.
+    NIX_CFLAGS_COMPILE = "-DDBUS_ENABLE_X11_AUTOLAUNCH=1";
+
+    installFlags = "sysconfdir=$(out)/etc";
+  };
+
+  tools = stdenv.mkDerivation {
+    name = "dbus-tools-" + version;
+
+    inherit src patches;
+
+    configureFlags = "${configureFlags} --with-dbus-daemondir=${daemon}/bin";
+
+    buildInputs = [ pkgconfig expat libs ]
+      ++ stdenv.lib.optionals useX11 [ libX11 libICE libSM ];
+
+    NIX_LDFLAGS = "-ldbus-1";
+
+    preConfigure =
+      ''
+        sed -i 's@ $(top_builddir)/dbus/libdbus-1.la@@' tools/Makefile.in
+        substituteInPlace tools/Makefile.in --replace 'install-localstatelibDATA:' 'disabled:'
+      '';
+
+    postConfigure = "cd tools";
+  };
+
+  # I'm too lazy to separate daemon and libs now.
+  daemon = libs;
+}