nixos/modules/programs/screen.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44

{ config, lib, pkgs, ... }:

let
  cfg = config.programs.screen;
in

{
  options = {
    programs.screen = {
      enable = lib.mkEnableOption "screen, a basic terminal multiplexer";

      package = lib.mkPackageOptionMD pkgs "screen" { };

      screenrc = lib.mkOption {
        type = lib.types.lines;
        default = "";
        example = ''
          defscrollback 10000
          startup_message off
        '';
        description = "The contents of {file}`/etc/screenrc` file";
      };
    };
  };

  config = lib.mkMerge [
    {
      # TODO: Added in 24.05, remove before 24.11
      assertions = [
        {
          assertion = cfg.screenrc != "" -> cfg.enable;
          message = "`programs.screen.screenrc` has been configured, but `programs.screen.enable` is not true";
        }
      ];
    }
    (lib.mkIf cfg.enable {
      environment.etc.screenrc = {
        text = cfg.screenrc;
      };
      environment.systemPackages = [ cfg.package ];
      security.pam.services.screen = {};
    })
  ];
}