nixos/modules/programs/weylus.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

{ config, lib, pkgs, ... }:

with lib;

let
  cfg = config.programs.weylus;
in
{
  options.programs.weylus = with types; {
    enable = mkEnableOption "weylus, which turns your smart phone into a graphic tablet/touch screen for your computer";

    openFirewall = mkOption {
      type = bool;
      default = false;
      description = ''
        Open ports needed for the functionality of the program.
      '';
    };

     users = mkOption {
      type = listOf str;
      default = [ ];
      description = ''
        To enable stylus and multi-touch support, the user you're going to use must be added to this list.
        These users can synthesize input events system-wide, even when another user is logged in - untrusted users should not be added.
      '';
    };

    package = mkPackageOption pkgs "weylus" { };
  };
  config = mkIf cfg.enable {
    networking.firewall = mkIf cfg.openFirewall {
      allowedTCPPorts = [ 1701 9001 ];
    };

    hardware.uinput.enable = true;

    users.groups.uinput.members = cfg.users;

    environment.systemPackages = [ cfg.package ];
  };
}