1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
|
{
lib,
# Optional due to unfree license.
faacSupport ? false,
fetchFromGitHub,
glib,
python3Packages,
gtk3,
wrapGAppsHook3,
gsettings-desktop-schemas,
intltool,
xvfb-run,
gobject-introspection,
gst_all_1,
fdk-aac-encoder,
}:
python3Packages.buildPythonApplication rec {
pname = "soundconverter";
version = "4.0.5";
src = fetchFromGitHub {
owner = "kassoulet";
repo = "soundconverter";
rev = version;
hash = "sha256-sno5EOh8HHfBTIE67VA8mheYp5wUMFRCbcS2EtKES3c=";
};
buildInputs = [
gtk3
fdk-aac-encoder
gst_all_1.gst-libav
gst_all_1.gst-plugins-base
gst_all_1.gst-plugins-good
gst_all_1.gst-plugins-ugly
(gst_all_1.gst-plugins-bad.override { inherit faacSupport; })
];
nativeBuildInputs = [
intltool
wrapGAppsHook3
gobject-introspection
];
dependencies = with python3Packages; [
gst-python
distutils-extra
setuptools
pygobject3
];
nativeCheckInputs = [ xvfb-run ];
postPatch = ''
substituteInPlace bin/soundconverter --replace \
"DATA_PATH = os.path.join(SOURCE_PATH, 'data')" \
"DATA_PATH = '$out/share/soundconverter'"
'';
preCheck =
let
self = {
outPath = "$out";
name = "${pname}-${version}";
};
xdgPaths = lib.concatMapStringsSep ":" glib.getSchemaDataDirPath;
in
''
export HOME=$TMPDIR
export XDG_DATA_DIRS=$XDG_DATA_DIRS:${
xdgPaths [
gtk3
gsettings-desktop-schemas
self
]
}
# FIXME: Fails due to weird Gio.file_parse_name() behavior.
sed -i '49 a\ @unittest.skip("Gio.file_parse_name issues")' tests/testcases/names.py
''
+ lib.optionalString (!faacSupport) ''
substituteInPlace tests/testcases/gui_integration.py --replace \
"for encoder in ['fdkaacenc', 'faac', 'avenc_aac']:" \
"for encoder in ['fdkaacenc', 'avenc_aac']:"
'';
checkPhase = ''
runHook preCheck
xvfb-run python tests/test.py
runHook postCheck
'';
# Necessary to set GDK_PIXBUF_MODULE_FILE.
strictDeps = false;
dontWrapGApps = true;
preFixup = ''
makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
'';
meta = {
homepage = "https://soundconverter.org/";
description = "Leading audio file converter for the GNOME Desktop";
mainProgram = "soundconverter";
longDescription = ''
SoundConverter reads anything the GStreamer library can read,
and writes WAV, FLAC, MP3, AAC and Ogg Vorbis files.
Uses Python and GTK+ GUI toolkit, and runs on X Window System.
'';
license = lib.licenses.gpl3Only;
platforms = lib.platforms.linux;
maintainers = with lib.maintainers; [
jakubgs
aleksana
];
};
}
|