blob: a8ce5ca242075990deb152b7d00c98f96cc383c0 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
|
{ lib
, rustPlatform
, fetchFromGitHub
, protobuf
, rustfmt
, stdenv
, darwin
, pkg-config
, openssl
}:
let
version = "0.2.0";
src = fetchFromGitHub {
owner = "talaia-labs";
repo = "rust-teos";
rev = "v${version}";
hash = "sha256-UrzH9xmhVq12TcSUQ1AihCG1sNGcy/N8LDsZINVKFkY=";
};
meta = with lib; {
homepage = "https://github.com/talaia-labs/rust-teos";
license = licenses.mit;
maintainers = with maintainers; [ seberm ];
};
in
{
teos = rustPlatform.buildRustPackage {
pname = "teos";
inherit version src;
cargoHash = "sha256-U0imKEPszlBOaS6xEd3kfzy/w2SYe3EY/E1e0L+ViDk=";
buildAndTestSubdir = "teos";
nativeBuildInputs = [
protobuf
rustfmt
];
buildInputs = lib.optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.Security
];
__darwinAllowLocalNetworking = true;
meta = meta // {
description = "A Lightning watchtower compliant with BOLT13, written in Rust";
};
};
teos-watchtower-plugin = rustPlatform.buildRustPackage {
pname = "teos-watchtower-plugin";
inherit version src;
cargoHash = "sha256-3ke1qTFw/4I5dPLuPjIGp1n2C/eRfPB7A6ErMFfwUzE=";
buildAndTestSubdir = "watchtower-plugin";
nativeBuildInputs = [
pkg-config
protobuf
rustfmt
];
buildInputs = [
openssl
] ++ lib.optionals stdenv.isDarwin [
darwin.apple_sdk.frameworks.SystemConfiguration
];
__darwinAllowLocalNetworking = true;
meta = meta // {
description = "A Lightning watchtower plugin for clightning";
mainProgram = "watchtower-client";
};
};
}
|
