blob: 66df76e1bac04e7e5a1c467e6ccfb7afbb7f2d83 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
{ lib
, stdenv
, fetchFromSourcehut
, SDL2
, unstableGitUpdater
}:
stdenv.mkDerivation (finalAttrs: {
pname = "uxn";
version = "unstable-2023-08-10";
src = fetchFromSourcehut {
owner = "~rabbits";
repo = "uxn";
rev = "a394dcb999525ac56ea37d0563d35849964b6d6a";
hash = "sha256-3Q8460pkoATKCEqfa+OfpQ4Lp18Ro5i84s88pkz+uzU=";
};
outputs = [ "out" "projects" ];
nativeBuildInputs = [
SDL2
];
buildInputs = [
SDL2
];
strictDeps = true;
postPatch = ''
patchShebangs build.sh
substituteInPlace build.sh \
--replace "-L/usr/local/lib " "" \
--replace "\$(brew --prefix)/lib/libSDL2.a " ""
'';
buildPhase = ''
runHook preBuild
./build.sh --no-run
runHook postBuild
'';
# ./build.sh --install is meant to install in $HOME, therefore not useful for
# package maintainers
installPhase = ''
runHook preInstall
install -d $out/bin/
cp bin/uxnasm bin/uxncli bin/uxnemu $out/bin/
install -d $projects/share/uxn/
cp -r projects $projects/share/uxn/
runHook postInstall
'';
passthru.updateScript = unstableGitUpdater { };
meta = {
homepage = "https://wiki.xxiivv.com/site/uxn.html";
description = "An assembler and emulator for the Uxn stack machine";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ AndersonTorres ];
mainProgram = "uxnemu";
inherit (SDL2.meta) platforms;
};
})
|