blob: bc27d93db6670c239439c6f52c0f2d9845b2e4b9 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
|
{ lib
, stdenv
, fetchFromGitHub
, makeWrapper
, xorg
, imlib2
, libjpeg
, libpng
, curl
, libexif
, jpegexiforient
, perl
, enableAutoreload ? !stdenv.hostPlatform.isDarwin
}:
stdenv.mkDerivation (finalAttrs: {
pname = "feh";
version = "3.10.3";
src = fetchFromGitHub {
owner = "derf";
repo = "feh";
rev = finalAttrs.version;
hash = "sha256-FtaFoLjI3HTLAxRTucp5VDYS73UuWqw9r9UWKK6T+og=";
};
outputs = [ "out" "man" "doc" ];
nativeBuildInputs = [ makeWrapper ];
buildInputs = [ xorg.libXt xorg.libX11 xorg.libXinerama imlib2 libjpeg libpng curl libexif ];
makeFlags = [
"PREFIX=${placeholder "out"}"
"exif=1"
] ++ lib.optional stdenv.isDarwin "verscmp=0"
++ lib.optional enableAutoreload "inotify=1";
installTargets = [ "install" ];
postInstall = ''
wrapProgram "$out/bin/feh" --prefix PATH : "${lib.makeBinPath [ libjpeg jpegexiforient ]}" \
--add-flags '--theme=feh'
'';
nativeCheckInputs = lib.singleton (perl.withPackages (p: [ p.TestCommand ]));
doCheck = true;
meta = with lib; {
description = "Light-weight image viewer";
homepage = "https://feh.finalrewind.org/";
# released under a variant of the MIT license
# https://spdx.org/licenses/MIT-feh.html
license = licenses.mit-feh;
maintainers = with maintainers; [ gepbird globin viric willibutz ];
platforms = platforms.unix;
mainProgram = "feh";
};
})
|
