1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{ stdenv
, lib
, fetchFromGitHub
, crystal
, wrapGAppsHook4
, desktopToDarwinBundle
, gobject-introspection
, gnome
, python3
, libadwaita
, openssl
, libxml2
, pkg-config
, gitUpdater
, _experimental-update-script-combinators
, runCommand
, crystal2nix
, writeShellScript
}:
crystal.buildCrystalPackage rec {
pname = "Collision";
version = "3.8.0";
src = fetchFromGitHub {
owner = "GeopJr";
repo = "Collision";
rev = "v${version}";
hash = "sha256-Bo/u0UYM/N7tLqdCs2OU5pdj2s9LXPooSR1PCGk9dSc=";
};
postPatch = ''
substituteInPlace Makefile \
--replace-fail 'gtk-update-icon-cache $(PREFIX)/share/icons/hicolor' 'true'
'';
shardsFile = ./shards.nix;
copyShardDeps = true;
preBuild = ''
cd lib/gi-crystal && shards build -Dpreview_mt --release --no-debug
cd ../.. && mkdir bin/ && cp lib/gi-crystal/bin/gi-crystal bin/
'';
# Crystal compiler has a strange issue with OpenSSL. The project will not compile due to
# main_module:(.text+0x6f0): undefined reference to `SSL_library_init'
# There is an explanation for this https://danilafe.com/blog/crystal_nix_revisited/
# Shortly, adding pkg-config to buildInputs along with openssl fixes the issue.
nativeBuildInputs = [ wrapGAppsHook4 pkg-config gobject-introspection ]
++ lib.optionals stdenv.isDarwin [ desktopToDarwinBundle ];
buildInputs = [
libadwaita
openssl
libxml2
gnome.nautilus-python
python3.pkgs.pygobject3
];
buildTargets = ["bindings" "build"];
doCheck = false;
doInstallCheck = false;
installTargets = ["desktop" "install"];
postInstall = ''
install -Dm555 ./nautilus-extension/collision-extension.py -t $out/share/nautilus-python/extensions
'';
passthru = {
updateScript = _experimental-update-script-combinators.sequence [
(gitUpdater { rev-prefix = "v"; })
(_experimental-update-script-combinators.copyAttrOutputToFile "collision.shardLock" ./shard.lock)
{ command = [ (writeShellScript "update-lock" "cd $1; ${lib.getExe crystal2nix}") ./. ]; supportedFeatures = [ "silent" ]; }
{ command = [ "rm" ./shard.lock ]; supportedFeatures = [ "silent" ]; }
];
shardLock = runCommand "shard.lock" { inherit src; } ''
cp $src/shard.lock $out
'';
};
meta = with lib; {
description = "Check hashes for your files";
homepage = "https://github.com/GeopJr/Collision";
license = licenses.bsd2;
mainProgram = "collision";
maintainers = with maintainers; [ sund3RRR ];
};
}
|
