blob: 35d2ab711794778607d8c886d92b093dacc1a6ca (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
|
{ lib
, stdenv
, fetchFromGitHub
, qtbase
, qmake
, qttools
, wrapQtAppsHook
}:
stdenv.mkDerivation rec {
pname = "cubiomes-viewer";
version = "4.0.1";
src = fetchFromGitHub {
owner = "Cubitect";
repo = pname;
rev = version;
sha256 = "sha256-UUvNSTM98r8D/Q+/pPTXwGzW4Sl1qhgem4WsFRfybuo=";
fetchSubmodules = true;
};
postPatch = ''
substituteInPlace cubiomes-viewer.pro \
--replace '$$[QT_INSTALL_BINS]/lupdate' lupdate \
--replace '$$[QT_INSTALL_BINS]/lrelease' lrelease
'';
buildInputs = [
qtbase
];
nativeBuildInputs = [
qmake
qttools
wrapQtAppsHook
];
preBuild = ''
# QMAKE_PRE_LINK is not executed (I dont know why)
make -C ./cubiomes libcubiomes CFLAGS="-DSTRUCT_CONFIG_OVERRIDE=1" all
'';
installPhase = ''
runHook preInstall
mkdir -p $out/bin
cp cubiomes-viewer $out/bin
mkdir -p $out/share/{pixmaps,applications}
cp rc/icons/map.png $out/share/pixmaps/com.github.cubitect.cubiomes-viewer.png
cp etc/com.github.cubitect.cubiomes-viewer.desktop $out/share/applications
runHook postInstall
'';
meta = with lib; {
broken = stdenv.isDarwin;
homepage = "https://github.com/Cubitect/cubiomes-viewer";
description = "Graphical Minecraft seed finder and map viewer";
mainProgram = "cubiomes-viewer";
longDescription = ''
Cubiomes Viewer provides a graphical interface for the efficient and flexible seed-finding
utilities provided by cubiomes and a map viewer for the Minecraft biomes and structure generation.
'';
platforms = platforms.all;
license = licenses.gpl3Plus;
maintainers = with maintainers; [ hqurve ];
};
}
|