1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
|
{ lib
, stdenv
, fetchFromGitHub
, fetchYarnDeps
, yarnConfigHook
, yarnBuildHook
, nodejs
, makeWrapper
, makeDesktopItem
, copyDesktopItems
, electron_29
}:
let
electron = electron_29;
in
stdenv.mkDerivation rec {
pname = "kuro";
version = "9.0.0";
src = fetchFromGitHub {
owner = "davidsmorais";
repo = "kuro";
rev = "v${version}";
hash = "sha256-9Z/r5T5ZI5aBghHmwiJcft/x/wTRzDlbIupujN2RFfU=";
};
offlineCache = fetchYarnDeps {
yarnLock = "${src}/yarn.lock";
hash = "sha256-GTiNv7u1QK/wjQgpka7REuoLn2wjZG59kYJQaZZPycI=";
};
env.ELECTRON_SKIP_BINARY_DOWNLOAD = "1";
nativeBuildInputs = [
yarnConfigHook
yarnBuildHook
nodejs
makeWrapper
copyDesktopItems
];
yarnBuildScript = "electron-builder";
yarnBuildFlags = [
"--dir"
"-c.electronDist=${electron}/libexec/electron"
"-c.electronVersion=${electron.version}"
];
installPhase = ''
runHook preInstall
# resources
mkdir -p "$out/share/lib/kuro"
cp -r ./dist/*-unpacked/{locales,resources{,.pak}} "$out/share/lib/kuro"
# icons
install -Dm644 ./static/Icon.png $out/share/icons/hicolor/1024x1024/apps/kuro.png
# executable wrapper
makeWrapper '${electron}/bin/electron' "$out/bin/kuro" \
--add-flags "$out/share/lib/kuro/resources/app.asar" \
--add-flags "\''${NIXOS_OZONE_WL:+\''${WAYLAND_DISPLAY:+--ozone-platform-hint=auto --enable-features=WaylandWindowDecorations}}" \
--inherit-argv0
runHook postInstall
'';
desktopItems = [
(makeDesktopItem {
name = "kuro";
exec = "kuro";
icon = "kuro";
desktopName = "Kuro";
genericName = "Microsoft To-Do Client";
comment = meta.description;
categories = [ "Office" ];
startupWMClass = "kuro";
})
];
meta = with lib; {
changelog = "https://github.com/davidsmorais/kuro/releases/tag/${src.rev}";
description = "An unofficial, featureful, open source, community-driven, free Microsoft To-Do app";
homepage = "https://github.com/davidsmorais/kuro";
license = licenses.mit;
mainProgram = "kuro";
maintainers = with maintainers; [ ChaosAttractor ];
inherit (electron.meta) platforms;
};
}
|