blob: 1ce8511b27c7b9a1d61ffc6eedc3f052b09359c2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
|
{ lib
, fetchFromGitHub
, python3
, dbus
, gnupg
, coreutils
, nixosTests
}:
python3.pkgs.buildPythonApplication rec {
pname = "pass-secret-service";
# PyPI has old alpha version. Since then the project has switched from using a
# seemingly abandoned D-Bus package pydbus and started using maintained
# dbus-next. So let's use latest from GitHub.
version = "unstable-2022-07-18";
src = fetchFromGitHub {
owner = "mdellweg";
repo = "pass_secret_service";
rev = "fadc09be718ae1e507eeb8719f3a2ea23edb6d7a";
hash = "sha256-lrNU5bkG4/fMu5rDywfiI8vNHyBsMf/fiWIeEHug03c=";
};
# Need to specify session.conf file for tests because it won't be found under
# /etc/ in check phase.
postPatch = ''
substituteInPlace Makefile \
--replace "dbus-run-session" "dbus-run-session --config-file=${dbus}/share/dbus-1/session.conf" \
--replace '-p $(relpassstore)' '-p $(PASSWORD_STORE_DIR)' \
--replace 'pytest-3' 'pytest'
substituteInPlace systemd/org.freedesktop.secrets.service \
--replace "/bin/false" "${coreutils}/bin/false"
substituteInPlace systemd/dbus-org.freedesktop.secrets.service \
--replace "/usr/local" "$out"
'';
postInstall = ''
mkdir -p "$out/share/dbus-1/services/" "$out/lib/systemd/user/"
cp systemd/org.freedesktop.secrets.service "$out/share/dbus-1/services/"
cp systemd/dbus-org.freedesktop.secrets.service "$out/lib/systemd/user/"
'';
propagatedBuildInputs = with python3.pkgs; [
click
cryptography
dbus-next
decorator
pypass
secretstorage
];
nativeCheckInputs =
let
ps = python3.pkgs;
in
[
dbus
gnupg
ps.pytest
ps.pytest-asyncio
ps.pypass
];
checkTarget = "test";
passthru.tests.pass-secret-service = nixosTests.pass-secret-service;
meta = {
description = "Libsecret D-Bus API with pass as the backend";
homepage = "https://github.com/mdellweg/pass_secret_service/";
license = lib.licenses.gpl3Only;
platforms = lib.platforms.all;
mainProgram = "pass_secret_service";
maintainers = with lib.maintainers; [ jluttine aidalgol ];
};
}
|
