pkgs/applications/misc/printrun/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48

{ lib, python3Packages, fetchFromGitHub, glib, wrapGAppsHook }:

python3Packages.buildPythonApplication rec {
  pname = "printrun";
  version = "2.0.0rc5";

  src = fetchFromGitHub {
    owner = "kliment";
    repo = "Printrun";
    rev = "${pname}-${version}";
    sha256 = "179x8lwrw2h7cxnkq7izny6qcb4nhjnd8zx893i77zfhzsa6kx81";
  };

  nativeBuildInputs = [ glib wrapGAppsHook ];

  propagatedBuildInputs = with python3Packages; [
    appdirs cython dbus-python numpy six wxPython_4_0 psutil pyglet pyopengl pyserial
  ];

  doCheck = false;

  setupPyBuildFlags = ["-i"];

  postPatch = ''
    sed -i -r "s|/usr(/local)?/share/|$out/share/|g" printrun/utils.py
  '';

  postInstall = ''
    for f in $out/share/applications/*.desktop; do
      sed -i -e "s|/usr/|$out/|g" "$f"
    done
  '';

  dontWrapGApps = true;
  # https://github.com/NixOS/nixpkgs/issues/56943
  strictDeps = false;

  preFixup = ''
    makeWrapperArgs+=("''${gappsWrapperArgs[@]}")
  '';

  meta = with lib; {
    description = "Pronterface, Pronsole, and Printcore - Pure Python 3d printing host software";
    homepage = "https://github.com/kliment/Printrun";
    license = licenses.gpl3;
    platforms = platforms.linux;
  };
}