1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
|
{ lib, stdenv, fetchFromGitHub, fetchpatch, buildPackages, cmake, installShellFiles
, boost, lua, protobuf, rapidjson, shapelib, sqlite, zlib, testers }:
stdenv.mkDerivation (finalAttrs: {
pname = "tilemaker";
version = "2.2.0";
src = fetchFromGitHub {
owner = "systemed";
repo = "tilemaker";
rev = "v${finalAttrs.version}";
hash = "sha256-st6WDCk1RZ2lbfrudtcD+zenntyTMRHrIXw3nX5FHOU=";
};
patches = [
# Fix build with Boost >= 1.79, remove on next upstream release
(fetchpatch {
url = "https://github.com/systemed/tilemaker/commit/252e7f2ad8938e38d51783d1596307dcd27ed269.patch";
hash = "sha256-YSkhmpzEYk/mxVPSDYdwZclooB3zKRjDPzqamv6Nvyc=";
})
];
postPatch = ''
substituteInPlace src/tilemaker.cpp \
--replace "config.json" "$out/share/tilemaker/config-openmaptiles.json" \
--replace "process.lua" "$out/share/tilemaker/process-openmaptiles.lua"
'';
nativeBuildInputs = [ cmake installShellFiles ];
buildInputs = [ boost lua protobuf rapidjson shapelib sqlite zlib ];
cmakeFlags = lib.optional (stdenv.hostPlatform != stdenv.buildPlatform)
"-DPROTOBUF_PROTOC_EXECUTABLE=${buildPackages.protobuf}/bin/protoc";
NIX_CFLAGS_COMPILE = [ "-DTM_VERSION=${finalAttrs.version}" ];
postInstall = ''
installManPage ../docs/man/tilemaker.1
install -Dm644 ../resources/* -t $out/share/tilemaker
'';
passthru.tests.version = testers.testVersion {
package = finalAttrs.finalPackage;
command = "tilemaker --help";
};
meta = with lib; {
description = "Make OpenStreetMap vector tiles without the stack";
homepage = "https://tilemaker.org/";
license = licenses.free; # FTWPL
maintainers = with maintainers; [ sikmir ];
platforms = platforms.unix;
};
})
|