blob: 03188bd6eeca9dcc3fa8f4da80d4e8ac91f422d0 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
{ lib, buildGoModule, fetchFromGitHub, installShellFiles, testers, clusterctl }:
buildGoModule rec {
pname = "clusterctl";
version = "1.7.4";
src = fetchFromGitHub {
owner = "kubernetes-sigs";
repo = "cluster-api";
rev = "v${version}";
hash = "sha256-ziW+ROuUmrgsIWHXKL2Yw+9gC6VgE/7Ri3zc3sveyU8=";
};
vendorHash = "sha256-ALRnccGjPGuAITtuz79Cao95NhvSczAzspSMXytlw+A=";
subPackages = [ "cmd/clusterctl" ];
nativeBuildInputs = [ installShellFiles ];
ldflags = let t = "sigs.k8s.io/cluster-api/version"; in [
"-X ${t}.gitMajor=${lib.versions.major version}"
"-X ${t}.gitMinor=${lib.versions.minor version}"
"-X ${t}.gitVersion=v${version}"
];
postInstall = ''
# errors attempting to write config to read-only $HOME
export HOME=$TMPDIR
installShellCompletion --cmd clusterctl \
--bash <($out/bin/clusterctl completion bash) \
--fish <($out/bin/clusterctl completion fish) \
--zsh <($out/bin/clusterctl completion zsh)
'';
passthru.tests.version = testers.testVersion {
package = clusterctl;
command = "HOME=$TMPDIR clusterctl version";
version = "v${version}";
};
meta = {
changelog = "https://github.com/kubernetes-sigs/cluster-api/releases/tag/${src.rev}";
description = "Kubernetes cluster API tool";
mainProgram = "clusterctl";
homepage = "https://cluster-api.sigs.k8s.io/";
license = lib.licenses.asl20;
maintainers = with lib.maintainers; [ qjoly ];
};
}
|