blob: b976308c4d8aa20ec4a25f7cbf6985753813fbb5 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
{ lib, buildGoModule, fetchFromGitHub, installShellFiles }:
buildGoModule rec {
pname = "driftctl";
version = "0.40.0";
src = fetchFromGitHub {
owner = "snyk";
repo = "driftctl";
rev = "v${version}";
sha256 = "sha256-IDKfW0NCEsgKXpHA7SwkHjMeoGAIYITlDVR/vI/b9hk=";
};
vendorHash = "sha256-JFvC9PReziktHSXbltGkGHjVR8hTM1hPJ0OqrZQXRQM=";
nativeBuildInputs = [ installShellFiles ];
ldflags = [
"-s"
"-w"
"-X github.com/snyk/driftctl/pkg/version.version=v${version}"
"-X github.com/snyk/driftctl/build.env=release"
"-X github.com/snyk/driftctl/build.enableUsageReporting=false"
];
postInstall = ''
installShellCompletion --cmd driftctl \
--bash <($out/bin/driftctl completion bash) \
--fish <($out/bin/driftctl completion fish) \
--zsh <($out/bin/driftctl completion zsh)
'';
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/driftctl --help
$out/bin/driftctl version | grep "v${version}"
# check there's no telemetry flag
$out/bin/driftctl --help | grep -vz "telemetry"
runHook postInstallCheck
'';
meta = with lib; {
homepage = "https://driftctl.com/";
changelog = "https://github.com/snyk/driftctl/releases/tag/v${version}";
description = "Detect, track and alert on infrastructure drift";
mainProgram = "driftctl";
longDescription = ''
driftctl is a free and open-source CLI that warns of infrastructure drift
and fills in the missing piece in your DevSecOps toolbox.
'';
license = licenses.asl20;
maintainers = with maintainers; [ kaction jk qjoly ];
};
}
|