1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
|
{ lib
, stdenv
, darwin
, fetchFromGitHub
, rustPlatform
, nixosTests
, nix-update-script
, autoPatchelfHook
, cmake
, ncurses
, pkg-config
, gcc-unwrapped
, fontconfig
, libGL
, vulkan-loader
, libxkbcommon
, withX11 ? !stdenv.isDarwin
, libX11
, libXcursor
, libXi
, libXrandr
, libxcb
, withWayland ? !stdenv.isDarwin
, wayland
, testers
, rio
}:
let
rlinkLibs = if stdenv.isDarwin then [
darwin.libobjc
darwin.apple_sdk_11_0.frameworks.AppKit
darwin.apple_sdk_11_0.frameworks.AVFoundation
darwin.apple_sdk_11_0.frameworks.MetalKit
darwin.apple_sdk_11_0.frameworks.Vision
] else [
(lib.getLib gcc-unwrapped)
fontconfig
libGL
libxkbcommon
vulkan-loader
] ++ lib.optionals withX11 [
libX11
libXcursor
libXi
libXrandr
libxcb
] ++ lib.optionals withWayland [
wayland
];
in
rustPlatform.buildRustPackage rec {
pname = "rio";
version = "0.1.1";
src = fetchFromGitHub {
owner = "raphamorim";
repo = "rio";
rev = "refs/tags/v${version}";
hash = "sha256-Hll9QpCN0/NDJ3tgJFnmNjfIotppGg5/BrHMxGmxOTo=";
};
cargoHash = "sha256-yyxJi0kK2d2I+9GncYHcRKbdngYSltDjsTuChqaDG/U=";
nativeBuildInputs = [
ncurses
] ++ lib.optionals stdenv.isLinux [
cmake
pkg-config
autoPatchelfHook
];
runtimeDependencies = rlinkLibs;
buildInputs = rlinkLibs;
outputs = [ "out" "terminfo" ];
buildNoDefaultFeatures = true;
buildFeatures = [ ]
++ lib.optional withX11 "x11"
++ lib.optional withWayland "wayland";
checkFlags = [
# Fail to run in sandbox environment.
"--skip=screen::context::test"
];
postInstall = ''
install -D -m 644 misc/rio.desktop -t $out/share/applications
install -D -m 644 misc/logo.svg \
$out/share/icons/hicolor/scalable/apps/rio.svg
install -dm 755 "$terminfo/share/terminfo/r/"
tic -xe rio,rio-direct -o "$terminfo/share/terminfo" misc/rio.terminfo
mkdir -p $out/nix-support
echo "$terminfo" >> $out/nix-support/propagated-user-env-packages
'' + lib.optionalString stdenv.isDarwin ''
mkdir $out/Applications/
mv misc/osx/Rio.app/ $out/Applications/
mkdir $out/Applications/Rio.app/Contents/MacOS/
ln -s $out/bin/rio $out/Applications/Rio.app/Contents/MacOS/
'';
passthru = {
updateScript = nix-update-script {
extraArgs = [ "--version-regex" "v([0-9.]+)" ];
};
tests = {
test = nixosTests.terminal-emulators.rio;
version = testers.testVersion { package = rio; };
};
};
meta = {
description = "Hardware-accelerated GPU terminal emulator powered by WebGPU";
homepage = "https://raphamorim.io/rio";
license = lib.licenses.mit;
maintainers = with lib.maintainers; [ tornax otavio oluceps ];
platforms = lib.platforms.unix;
changelog = "https://github.com/raphamorim/rio/blob/v${version}/CHANGELOG.md";
mainProgram = "rio";
# ---- corcovado/src/sys/unix/eventedfd.rs - sys::unix::eventedfd::EventedFd (line 31) stdout ----
# Test executable failed (exit status: 101).
# stderr:
# thread 'main' panicked at corcovado/src/sys/unix/eventedfd.rs:24:16:
# called `Result::unwrap()` on an `Err` value: Os { code: 1, kind: PermissionDenied, message: "Operation not permitted" }
broken = stdenv.isDarwin;
};
}
|