1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
|
{ lib
, fetchFromGitHub
, stdenv
, wrapQtAppsHook
, substituteAll
, SDL2
, frei0r
, ladspaPlugins
, gettext
, mlt
, jack1
, pkg-config
, fftw
, qtbase
, qttools
, qtmultimedia
, qtcharts
, cmake
, gitUpdater
}:
stdenv.mkDerivation rec {
pname = "shotcut";
version = "23.11.29";
src = fetchFromGitHub {
owner = "mltframework";
repo = "shotcut";
rev = "v${version}";
hash = "sha256-szWXX/DIJk5ktESgecglptU1qrnrd/u0N6AffwZ5Tos=";
};
nativeBuildInputs = [ pkg-config cmake wrapQtAppsHook ];
buildInputs = [
SDL2
frei0r
ladspaPlugins
gettext
mlt
fftw
qtbase
qttools
qtmultimedia
qtcharts
];
env.NIX_CFLAGS_COMPILE = "-DSHOTCUT_NOUPGRADE";
cmakeFlags = [
"-DSHOTCUT_VERSION=${version}"
];
patches = [
(substituteAll { inherit mlt; src = ./fix-mlt-ffmpeg-path.patch; })
];
qtWrapperArgs = [
"--set FREI0R_PATH ${frei0r}/lib/frei0r-1"
"--set LADSPA_PATH ${ladspaPlugins}/lib/ladspa"
"--prefix LD_LIBRARY_PATH : ${lib.makeLibraryPath [jack1 SDL2]}"
];
passthru.updateScript = gitUpdater {
rev-prefix = "v";
};
meta = with lib; {
description = "A free, open source, cross-platform video editor";
longDescription = ''
An official binary for Shotcut, which includes all the
dependencies pinned to specific versions, is provided on
http://shotcut.org.
If you encounter problems with this version, please contact the
nixpkgs maintainer(s). If you wish to report any bugs upstream,
please use the official build from shotcut.org instead.
'';
homepage = "https://shotcut.org";
license = licenses.gpl3Plus;
maintainers = with maintainers; [ goibhniu woffs peti ];
platforms = platforms.linux;
mainProgram = "shotcut";
};
}
|