pkgs/applications/video/vcs/default.nix


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42

{ lib, stdenv, fetchurl, makeWrapper
, coreutils, ffmpeg, gawk, gnugrep, gnused, imagemagick, mplayer
, util-linux, getopt
, dejavu_fonts
}:
let
  version = "1.13.4";
  gopt = if stdenv.isLinux then util-linux else getopt;
  runtimeDeps = [
    coreutils ffmpeg gawk gnugrep gnused imagemagick mplayer gopt
  ];
in
stdenv.mkDerivation {
  pname = "vcs";
  inherit version;
  src = fetchurl {
    url = "http://p.outlyer.net/files/vcs/vcs-${version}.bash";
    sha256 = "0nhwcpffp3skz24kdfg4445i6j37ks6a0qsbpfd3dbi4vnpa60a0";
  };

  unpackCmd = "mkdir src; cp $curSrc src/vcs";
  patches = [ ./fonts.patch ];
  nativeBuildInputs = [ makeWrapper ];

  inherit dejavu_fonts;
  installPhase = ''
    mkdir -p $out/bin
    mv vcs $out/bin/vcs
    substituteAllInPlace $out/bin/vcs
    chmod +x $out/bin/vcs
    wrapProgram $out/bin/vcs --argv0 vcs --set PATH "${lib.makeBinPath runtimeDeps}"
  '';

  meta = with lib; {
    description = "Generates contact sheets from video files";
    homepage = "http://p.outlyer.net/vcs";
    license = licenses.lgpl21Plus;
    maintainers = with maintainers; [ elitak ];
    platforms = with platforms; unix;
    mainProgram = "vcs";
  };
}