blob: bbcc4f0c0f7100f538d922ae88a0ab2a28b1d117 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
|
# Static arguments
{ lib, runCommand, pkg-config }:
# Tester arguments
{ package,
moduleNames ? package.meta.pkgConfigModules,
testName ? "check-pkg-config-${lib.concatStringsSep "-" moduleNames}",
}:
runCommand testName {
nativeBuildInputs = [ pkg-config ];
buildInputs = [ package ];
inherit moduleNames;
meta = {
description = "Test whether ${package.name} exposes pkg-config modules ${lib.concatStringsSep ", " moduleNames}.";
}
# Make sure licensing info etc is preserved, as this is a concern for e.g. cache.nixos.org,
# as hydra can't check this meta info in dependencies.
# The test itself is just Nixpkgs, with MIT license.
// builtins.intersectAttrs
{
available = throw "unused";
broken = throw "unused";
insecure = throw "unused";
license = throw "unused";
maintainers = throw "unused";
platforms = throw "unused";
unfree = throw "unused";
unsupported = throw "unused";
}
package.meta;
} ''
touch "$out"
for moduleName in $moduleNames; do
echo "checking pkg-config module $moduleName in $buildInputs"
set +e
version="$($PKG_CONFIG --modversion $moduleName)"
r=$?
set -e
if [[ $r = 0 ]]; then
echo "✅ pkg-config module $moduleName exists and has version $version"
printf '%s\t%s\n' "$moduleName" "$version" >> "$out"
else
echo "These modules were available in the input propagation closure:"
$PKG_CONFIG --list-all
echo "❌ pkg-config module $moduleName was not found"
false
fi
done
''
|