1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
|
{
lib,
python3Packages,
fetchFromGitHub,
appstream,
meson,
ninja,
pkg-config,
gobject-introspection,
wrapGAppsHook4,
desktop-file-utils,
libadwaita,
gtksourceview5,
xdg-utils,
ollama,
}:
python3Packages.buildPythonApplication rec {
pname = "alpaca";
version = "1.0.1";
pyproject = false; # Built with meson
src = fetchFromGitHub {
owner = "Jeffser";
repo = "Alpaca";
rev = version;
hash = "sha256-GxnYPnrjaJ47/i+pigw+on2dmbHwQSX+STasvqnAtuQ=";
};
patches = [
# Change the way XDG paths are handled so it makes sense outside of flatpak
./fix_xdg_path_flatpak.patch
];
postPatch = ''
substituteInPlace src/local_instance.py \
--replace-fail '/app/bin/ollama' 'ollama'
substituteInPlace src/window.py \
--replace-fail '/app/share' "$out/share"
'';
nativeBuildInputs = [
appstream
meson
ninja
pkg-config
gobject-introspection
wrapGAppsHook4
desktop-file-utils
];
buildInputs = [
libadwaita
gtksourceview5
];
dependencies = with python3Packages; [
pygobject3
requests
pillow
pypdf
pytube
html2text
];
dontWrapGApps = true;
makeWrapperArgs = [
"\${gappsWrapperArgs[@]}"
"--prefix PATH : ${lib.makeBinPath [ xdg-utils ollama ]}"
# Declared but not used in src/window.py, for later reference
# https://github.com/flatpak/flatpak/issues/3229
"--set FLATPAK_DEST ${placeholder "out"}"
];
meta = {
description = "Ollama client made with GTK4 and Adwaita";
longDescription = ''
To run Alpaca with GPU acceleration enabled, simply override it:
```nix
pkgs.alpaca.override {
ollama = pkgs.ollama-cuda;
}
```
Or using `pkgs.ollama-rocm` for AMD GPUs.
'';
homepage = "https://jeffser.com/alpaca";
license = lib.licenses.gpl3Plus;
mainProgram = "alpaca";
maintainers = with lib.maintainers; [ aleksana ];
platforms = lib.platforms.linux;
};
}
|
