blob: 97d3d5b99d3c3d54cfb8fec28e37c9988c0a8cd2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
|
{
lib,
stdenv,
fetchurl,
appimageTools,
makeWrapper,
autoPatchelfHook,
libgcc,
appVariants ? [ ],
}:
let
pname = "caido";
appVariantList = [
"cli"
"desktop"
];
version = "0.39.0";
cli = fetchurl {
url = "https://storage.googleapis.com/caido-releases/v${version}/caido-cli-v${version}-linux-x86_64.tar.gz";
hash = "sha256-I8UF2rzIKfpcrxyvDa4AReWDIHOKTCj3ERaWhG1xGG0=";
};
desktop = fetchurl {
url = "https://storage.googleapis.com/caido-releases/v${version}/caido-desktop-v${version}-linux-x86_64.AppImage";
hash = "sha256-KYQck2+YYPLJN3L6qchacjyVyyXR3nmJDTX5GPB4WvI=";
};
appimageContents = appimageTools.extractType2 {
inherit pname version;
src = desktop;
};
wrappedDesktop = appimageTools.wrapType2 {
src = desktop;
inherit pname version;
extraPkgs = pkgs: [ pkgs.libthai ];
extraInstallCommands = ''
install -m 444 -D ${appimageContents}/caido.desktop -t $out/share/applications
install -m 444 -D ${appimageContents}/caido.png \
$out/share/icons/hicolor/512x512/apps/caido.png
source "${makeWrapper}/nix-support/setup-hook"
wrapProgram $out/bin/caido \
--set WEBKIT_DISABLE_COMPOSITING_MODE 1
'';
};
wrappedCli = stdenv.mkDerivation {
src = cli;
inherit pname version;
nativeBuildInputs = [ autoPatchelfHook ];
buildInputs = [ libgcc ];
sourceRoot = ".";
installPhase = ''
runHook preInstall
install -m755 -D caido-cli $out/bin/caido-cli
'';
};
meta = {
description = "Lightweight web security auditing toolkit";
homepage = "https://caido.io/";
changelog = "https://github.com/caido/caido/releases/tag/v${version}";
license = lib.licenses.unfree;
maintainers = with lib.maintainers; [
octodi
d3vil0p3r
];
platforms = [ "x86_64-linux" ];
};
in
lib.checkListOfEnum "${pname}: appVariants" appVariantList appVariants (
if appVariants == [ "desktop" ] then
wrappedDesktop
else if appVariants == [ "cli" ] then
wrappedCli
else
stdenv.mkDerivation {
inherit pname version meta;
dontUnpack = true;
installPhase = ''
mkdir -p $out/bin
ln -s ${wrappedDesktop}/bin/caido $out/bin/caido
ln -s ${wrappedCli}/bin/caido-cli $out/bin/caido-cli
'';
}
)
|
