blob: 61cad3e9682e1bc92ff6e2168461e270569095f2 (
plain) (
blame)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
|
{
lib,
buildNpmPackage,
fetchFromGitHub,
jre,
maven,
makeWrapper,
nixosTests,
writeText,
}:
let
version = "4.3.3";
src = fetchFromGitHub {
owner = "Athou";
repo = "commafeed";
rev = version;
hash = "sha256-y0gTmtlDg7sdunG1ne/3WkFx2KQkTGRlfYpXBHFFh2o=";
};
frontend = buildNpmPackage {
inherit version src;
pname = "commafeed-frontend";
sourceRoot = "${src.name}/commafeed-client";
npmDepsHash = "sha256-fye7MPWXUeFCMgcnesspd1giGG/ZldiOv00fjtXZSb4=";
installPhase = ''
runHook preInstall
cp -r dist/ $out
runHook postInstall
'';
};
gitProperties = writeText "git.properties" ''
git.branch = none
git.build.time = 1970-01-01T00:00:00+0000
git.build.version = ${version}
git.commit.id = none
git.commit.id.abbrev = none
'';
in
maven.buildMavenPackage {
inherit version src;
pname = "commafeed";
mvnHash = "sha256-LDZv3CBc/FpVMKmZ+kqfBdkTbqZcJMRqeXN35t4rwJI=";
mvnParameters = lib.escapeShellArgs [
"-Dskip.installnodenpm"
"-Dskip.npm"
"-Dspotless.check.skip"
"-Dmaven.gitcommitid.skip"
];
nativeBuildInputs = [ makeWrapper ];
configurePhase = ''
runHook preConfigure
ln -sf "${frontend}" commafeed-client/dist
cp ${gitProperties} commafeed-server/src/main/resources/git.properties
runHook postConfigure
'';
doCheck = false;
installPhase = ''
runHook preInstall
mkdir -p $out/bin $out/share
install -Dm644 commafeed-server/target/commafeed.jar $out/share/commafeed.jar
install -Dm644 commafeed-server/config.yml.example $out/share/config.yml
makeWrapper ${jre}/bin/java $out/bin/commafeed \
--add-flags "-jar $out/share/commafeed.jar"
runHook postInstall
'';
postInstall = ''
substituteInPlace $out/share/config.yml \
--replace-fail 'url: jdbc:h2:/commafeed/data/db;DEFRAG_ALWAYS=TRUE' \
'url: jdbc:h2:./database/db;DEFRAG_ALWAYS=TRUE'
'';
passthru.tests = nixosTests.commafeed;
meta = {
description = "Google Reader inspired self-hosted RSS reader";
homepage = "https://github.com/Athou/commafeed";
license = lib.licenses.asl20;
mainProgram = "commafeed";
maintainers = [ lib.maintainers.raroh73 ];
};
}
|