1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
|
{
lib,
stdenv,
fetchCrate,
rustPlatform,
installShellFiles,
darwin,
libiconv,
libmysqlclient,
nix-update-script,
openssl,
pkg-config,
postgresql,
sqlite,
testers,
zlib,
diesel-cli,
sqliteSupport ? true,
postgresqlSupport ? true,
mysqlSupport ? true,
}:
assert lib.assertMsg (lib.elem true [
postgresqlSupport
mysqlSupport
sqliteSupport
]) "support for at least one database must be enabled";
rustPlatform.buildRustPackage rec {
pname = "diesel-cli";
version = "2.1.1";
src = fetchCrate {
inherit version;
crateName = "diesel_cli";
hash = "sha256-fpvC9C30DJy5ih+sFTTMoiykUHqG6OzDhF9jvix1Ctg=";
};
cargoHash = "sha256-nPmUCww8sOJwnG7+uIflLPgT87xPX0s7g0AcuDKhY2I=";
nativeBuildInputs = [
installShellFiles
pkg-config
];
buildInputs =
[ openssl ]
++ lib.optional stdenv.isDarwin darwin.apple_sdk.frameworks.Security
++ lib.optional (stdenv.isDarwin && mysqlSupport) libiconv
++ lib.optional sqliteSupport sqlite
++ lib.optional postgresqlSupport postgresql
++ lib.optionals mysqlSupport [
libmysqlclient
zlib
];
buildNoDefaultFeatures = true;
buildFeatures =
lib.optional sqliteSupport "sqlite"
++ lib.optional postgresqlSupport "postgres"
++ lib.optional mysqlSupport "mysql";
checkFlags = [
# all of these require a live database to be running
# `DATABASE_URL must be set in order to run tests: NotPresent`
"--skip=infer_schema_internals::information_schema::tests::get_primary_keys_only_includes_primary_key"
"--skip=infer_schema_internals::information_schema::tests::load_table_names_loads_from_custom_schema"
"--skip=infer_schema_internals::information_schema::tests::load_table_names_loads_from_public_schema_if_none_given"
"--skip=infer_schema_internals::information_schema::tests::load_table_names_output_is_ordered"
"--skip=infer_schema_internals::information_schema::tests::skip_views"
"--skip=infer_schema_internals::mysql::test::get_table_data_loads_column_information"
"--skip=infer_schema_internals::mysql::test::gets_table_comment"
"--skip=infer_schema_internals::pg::test::get_foreign_keys_loads_foreign_keys"
"--skip=infer_schema_internals::pg::test::get_foreign_keys_loads_foreign_keys_with_same_name"
"--skip=infer_schema_internals::pg::test::get_table_data_loads_column_information"
"--skip=infer_schema_internals::pg::test::gets_table_comment"
];
cargoCheckFeatures = buildFeatures;
postInstall = ''
installShellCompletion --cmd diesel \
--bash <($out/bin/diesel completions bash) \
--fish <($out/bin/diesel completions fish) \
--zsh <($out/bin/diesel completions zsh)
'';
# Fix the build with mariadb, which otherwise shows "error adding symbols:
# DSO missing from command line" errors for libz and libssl.
env.NIX_LDFLAGS = lib.optionalString mysqlSupport "-lz -lssl -lcrypto";
passthru = {
tests.version = testers.testVersion { package = diesel-cli; };
updateScript = nix-update-script { };
};
meta = {
description = "Database tool for working with Rust projects that use Diesel";
homepage = "https://diesel.rs";
changelog = "https://github.com/diesel-rs/diesel/releases/tag/v${version}";
license = with lib.licenses; [
mit
asl20
];
maintainers = with lib.maintainers; [ getchoo ];
mainProgram = "diesel";
};
}
|