1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
|
{ lib
, stdenv
, fetchFromGitHub
, autoreconfHook
, doxygen
, libglut
, freetype
, libGL
, libGLU
, pkg-config
, darwin
}:
let
inherit (darwin.apple_sdk.frameworks) OpenGL GLUT;
in
stdenv.mkDerivation rec {
pname = "ftgl";
version = "2.4.0";
src = fetchFromGitHub {
owner = "frankheckenbach";
repo = "ftgl";
rev = "v${version}";
hash = "sha256-6TDNGoMeBLnucmHRgEDIVWcjlJb7N0sTluqBwRMMWn4=";
};
# GL_DYLIB is hardcoded to an impure path
# /System/Library/Frameworks/OpenGL.framework/Versions/A/Libraries/libGL.dylib
# and breaks build on recent macOS versions
postPatch = ''
substituteInPlace m4/gl.m4 \
--replace ' -dylib_file $GL_DYLIB: $GL_DYLIB' ""
'';
nativeBuildInputs = [
autoreconfHook
doxygen
pkg-config
];
buildInputs = [
freetype
] ++ (if stdenv.hostPlatform.isDarwin then [
OpenGL
GLUT
] else [
libGL
libGLU
libglut
]);
configureFlags = [
"--with-ft-prefix=${lib.getDev freetype}"
];
enableParallelBuilding = true;
postInstall = ''
install -Dm644 src/FTSize.h -t ${placeholder "out"}/include/FTGL
install -Dm644 src/FTFace.h -t ${placeholder "out"}/include/FTGL
'';
meta = with lib; {
homepage = "https://github.com/frankheckenbach/ftgl";
description = "Font rendering library for OpenGL applications";
longDescription = ''
FTGL is a free cross-platform Open Source C++ library that uses Freetype2
to simplify rendering fonts in OpenGL applications. FTGL supports bitmaps,
pixmaps, texture maps, outlines, polygon mesh, and extruded polygon
rendering modes.
'';
license = licenses.mit;
maintainers = with maintainers; [ AndersonTorres ];
platforms = platforms.unix;
};
}
|
