1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
|
{
stdenv,
lib,
fetchFromGitHub,
unstableGitUpdater,
buildPackages,
gnu-efi,
mtools,
openssl,
perl,
xorriso,
xz,
syslinux,
embedScript ? null,
additionalTargets ? { },
additionalOptions ? [ ],
}:
let
targets =
additionalTargets
// lib.optionalAttrs stdenv.hostPlatform.isx86_64 {
"bin-x86_64-efi/ipxe.efi" = null;
"bin-x86_64-efi/ipxe.efirom" = null;
"bin-x86_64-efi/ipxe.usb" = "ipxe-efi.usb";
"bin-x86_64-efi/snp.efi" = null;
}
// lib.optionalAttrs stdenv.hostPlatform.isx86 {
"bin/ipxe.dsk" = null;
"bin/ipxe.usb" = null;
"bin/ipxe.iso" = null;
"bin/ipxe.lkrn" = null;
"bin/undionly.kpxe" = null;
}
// lib.optionalAttrs stdenv.hostPlatform.isAarch32 {
"bin-arm32-efi/ipxe.efi" = null;
"bin-arm32-efi/ipxe.efirom" = null;
"bin-arm32-efi/ipxe.usb" = "ipxe-efi.usb";
"bin-arm32-efi/snp.efi" = null;
}
// lib.optionalAttrs stdenv.hostPlatform.isAarch64 {
"bin-arm64-efi/ipxe.efi" = null;
"bin-arm64-efi/ipxe.efirom" = null;
"bin-arm64-efi/ipxe.usb" = "ipxe-efi.usb";
"bin-arm64-efi/snp.efi" = null;
};
in
stdenv.mkDerivation (finalAttrs: {
pname = "ipxe";
version = "1.21.1-unstable-2024-09-13";
nativeBuildInputs = [
gnu-efi
mtools
openssl
perl
xorriso
xz
] ++ lib.optional stdenv.hostPlatform.isx86 syslinux;
depsBuildBuild = [ buildPackages.stdenv.cc ];
strictDeps = true;
src = fetchFromGitHub {
owner = "ipxe";
repo = "ipxe";
rev = "c85ad1246890cf3c0c5f2ac6de06ab046ddd0043";
hash = "sha256-Py0mXcCj/NhVW3crngR9ZLHvH9N0QJeVmykc3k+yi6Y=";
};
# Calling syslinux on a FAT image isn't going to work on Aarch64.
postPatch = lib.optionalString stdenv.hostPlatform.isAarch64 ''
substituteInPlace src/util/genfsimg --replace " syslinux " " true "
'';
# Hardening is not possible due to assembler code.
hardeningDisable = [
"pic"
"stackprotector"
];
makeFlags = [
"ECHO_E_BIN_ECHO=echo"
"ECHO_E_BIN_ECHO_E=echo" # No /bin/echo here.
"CROSS=${stdenv.cc.targetPrefix}"
] ++ lib.optional (embedScript != null) "EMBED=${embedScript}";
enabledOptions = [
"PING_CMD"
"IMAGE_TRUST_CMD"
"DOWNLOAD_PROTO_HTTP"
"DOWNLOAD_PROTO_HTTPS"
] ++ additionalOptions;
configurePhase =
''
runHook preConfigure
for opt in ${lib.escapeShellArgs finalAttrs.enabledOptions}; do echo "#define $opt" >> src/config/general.h; done
substituteInPlace src/Makefile.housekeeping --replace '/bin/echo' echo
''
+ lib.optionalString stdenv.hostPlatform.isx86 ''
substituteInPlace src/util/genfsimg --replace /usr/lib/syslinux ${syslinux}/share/syslinux
''
+ ''
runHook postConfigure
'';
preBuild = "cd src";
buildFlags = lib.attrNames targets;
installPhase = ''
runHook preInstall
mkdir -p $out
${lib.concatStringsSep "\n" (
lib.mapAttrsToList (
from: to: if to == null then "cp -v ${from} $out" else "cp -v ${from} $out/${to}"
) targets
)}
# Some PXE constellations especially with dnsmasq are looking for the file with .0 ending
# let's provide it as a symlink to be compatible in this case.
ln -s undionly.kpxe $out/undionly.kpxe.0
runHook postInstall
'';
enableParallelBuilding = true;
passthru.updateScript = unstableGitUpdater {
tagPrefix = "v";
};
meta = {
description = "Network boot firmware";
homepage = "https://ipxe.org/";
license = lib.licenses.gpl2Only;
platforms = lib.platforms.linux;
maintainers = with lib.maintainers; [ sigmasquadron ];
};
})
|
